Why , in pase tree , ANTLR keep mismatching input? - antlr

Question

I am new with ANTLR4 and I am trying to visualize the Parse Tree of a text input in a simple form :
grammar Expr;
contract: (I WS SEND WS quantity WS asset WS TO WS beneficiary WS ON WS send_date WS)*;
asset: '$'| 'TND' | 'USD';
quantity:Q;
beneficiary: B;
send_date : day SLASH month SLASH year;
day: D ;
month: M ;
year: Y ;
B : LETTERUP (LETTERLOW+)+ LETTERLOW*;
Q : DIGITO DIGITZ*|DIGITO DIGITZ* POINT DIGITZ*;
D : DIGIT0 DIGITO|(DIGIT1|DIGIT2)DIGITZ|DIGIT3(DIGIT0|DIGIT1);
M : DIGIT0 DIGITO| DIGIT1(DIGIT0|DIGIT1|DIGIT2);
Y : DIGIT2 DIGIT0((DIGIT1(DIGIT7|DIGIT8|DIGIT9))|(DIGIT2 DIGITZ));
I: 'I';
SEND: 'send';
TO:'to' ;
ON: 'on';
LETTER : [a-zA-Z];
LETTERUP : [A-Z];
LETTERLOW : [a-z];
DIGITZ : [0-9];
DIGITO : [1-9];
DIGIT0 : [0];
DIGIT1 : [1];
DIGIT2 : [2];
DIGIT3 : [3];
DIGIT4 : [4];
DIGIT5 : [5];
DIGIT6 : [6];
DIGIT7 : [7];
DIGIT8 : [8];
DIGIT9 : [9];
SLASH:'/';
POINT:'.'|',';
WS : (' ' | '\t' |'\n' |'\r' )+ ;
But it keeps mismatching the send_date as you can see here:
I know it is a seriously complex numerical grammar I did just want some control the 01<= day <= 31 , 01<= month <= 12 and 2017<= year <= 2029 that's all
is there any help? and thanks

Answer 1

The problem happens because your grammar is ambiguous. 07 can match D and 2017 can match Q.
You can fix it like this:
grammar Expr;
contract: (I WS SEND WS quantity WS asset WS TO WS beneficiary WS ON WS send_date WS)*;
asset: '$'| 'TND' | 'USD';
quantity:Q;
beneficiary: B;
send_date : day month year ;
day: D ;
month: M ;
year: Y ;
D : DIGIT0 DIGITO|(DIGIT1|DIGIT2)DIGITZ|DIGIT3(DIGIT0|DIGIT1);
M : SLASH (DIGIT0 DIGITO| DIGIT1(DIGIT0|DIGIT1|DIGIT2));
Y : SLASH (DIGIT2 DIGIT0((DIGIT1(DIGIT7|DIGIT8|DIGIT9))|(DIGIT2 DIGITZ)));
B : LETTERUP (LETTERLOW+)+ LETTERLOW*;
Q : DIGITO DIGITZ*|DIGITO DIGITZ* POINT DIGITZ*;
I: 'I';
SEND: 'send';
TO:'to' ;
ON: 'on';
LETTER : [a-zA-Z];
LETTERUP : [A-Z];
LETTERLOW : [a-z];
DIGITZ : [0-9];
DIGITO : [1-9];
DIGIT0 : [0];
DIGIT1 : [1];
DIGIT2 : [2];
DIGIT3 : [3];
DIGIT4 : [4];
DIGIT5 : [5];
DIGIT6 : [6];
DIGIT7 : [7];
DIGIT8 : [8];
DIGIT9 : [9];
SLASH:'/';
POINT:'.'|',';
WS : (' ' | '\t' |'\n' |'\r' )+ ;

Answer 2

That's a seriously complex numerical grammar. Perhaps you could simplify:
day: NUMBER ;
month: NUMBER ;
year: NUMBER ;
NUMBER : DIGITZ+ ;
DIGITZ : [0-9];
You could enforce semantics like limiting year to [2017...2020] or whatever in your code. Just an idea. Simplifying often helps and then you can enhance it from there, knowing if you make a mistake you can always revert to something that will at least work.
EDIT:
The reason your grammar doesn't work is because the month is being lexed as a day:
[#0,0:0='I',<'I'>,1:0]
[#1,1:1=' ',<WS>,1:1]
[#2,2:5='send',<'send'>,1:2]
[#3,6:6=' ',<WS>,1:6]
[#4,7:9='300',<Q>,1:7]
[#5,10:10=' ',<WS>,1:10]
[#6,11:11='$',<'$'>,1:11]
[#7,12:12=' ',<WS>,1:12]
[#8,13:14='to',<'to'>,1:13]
[#9,15:15=' ',<WS>,1:15]
[#10,16:20='Ahmed',<B>,1:16]
[#11,21:21=' ',<WS>,1:21]
[#12,22:23='on',<'on'>,1:22]
[#13,24:24=' ',<WS>,1:24]
[#14,25:26='03',<D>,1:25]
[#15,27:27='/',<'/'>,1:27]
[#16,28:29='07',<D>,1:28] <-- see, this is being lexed as a D (day)
[#17,30:30='/',<'/'>,1:30]
[#18,31:34='2017',<Q>,1:31] <-- and this is being lexed as a Q (quantity)
[#19,35:36='\r\n',<WS>,1:35]
[#20,37:36='<EOF>',<EOF>,2:0]
line 1:28 mismatched input '05' expecting M
line 1:31 mismatched input '2017' expecting Y
Lexer rules are applied in the order in which they appear, and Day appears before Month. Quantity appears before Year. Hence the improper lexing. This is a scenario, honestly, where I think you need to simplify and just accept numbers. Then in your code, enforce the semantics (make sure year is in range, etc) in your code and provide a helpful error message to the user if values are not in range. Your total effort spend will be less that way.
NEW VERSION
grammar Test2;
contract: (I SEND quantity asset TO beneficiary ON send_date)*;
asset: '$'| 'TND' | 'USD';
send_date : DATE ;
quantity: NUMBER;
beneficiary: B;
DATE : NUMBER SLASH NUMBER SLASH NUMBER ;
B : LETTERUP (LETTERLOW+)+ LETTERLOW*;
I: 'I';
SEND: 'send';
TO:'to' ;
ON: 'on';
LETTER : [a-zA-Z];
LETTERUP : [A-Z];
LETTERLOW : [a-z];
NUMBER: DIGIT+;
DIGIT : [0-9];
SLASH:'/';
POINT:'.'|',';
WS : [ \t\n\r]+ -> skip;
Improvements:
1. Better handling of whitespace much more conventional.
2. Simplified number syntax.
3. It works
[#0,0:0='I',<'I'>,1:0]
[#1,2:5='send',<'send'>,1:2]
[#2,7:9='300',<NUMBER>,1:7]
[#3,11:11='$',<'$'>,1:11]
[#4,13:14='to',<'to'>,1:13]
[#5,16:20='Ahmed',<B>,1:16]
[#6,22:23='on',<'on'>,1:22]
[#7,25:34='03/07/2017',<DATE>,1:25]
[#8,37:36='<EOF>',<EOF>,2:0]
Problem: I simplified away the ability to do decimal numbers for quantity. You can add that back in as you wish.