Case vba is skipping over the correct case - vba

Question

Dim score As Variant
score = Range("KPI!A6").Value
Select Case score
Case score = "January"
Columns("D:N").EntireColumn.Hidden = True
Case score = "February"
Columns("C:C,E:N").EntireColumn.Hidden = True
Case score = "March"
Columns("C:D,F:N").EntireColumn.Hidden = True
Case score = "April"
Columns("C:E,G:N").EntireColumn.Hidden = True
Case score = "May"
Columns("C:F,H:N").EntireColumn.Hidden = True
Case score = "June"
Columns("C:G,I:N").EntireColumn.Hidden = True
Case score = "July"
Columns("C:H,J:N").EntireColumn.Hidden = True
Case score = "August"
Columns("C:I,K:N").EntireColumn.Hidden = True
Case score = "September"
Columns("C:J,L:N").EntireColumn.Hidden = True
Case score = "October"
Columns("C:K,M:N").EntireColumn.Hidden = True
Case score = "November"
Columns("C:L,N:N").EntireColumn.Hidden = True
Case score = "December"
Columns("C:M").EntireColumn.Hidden = True
End Select
End Sub
Hey all! This is my first question, so hopefully I'm not doing things incorrectly. In any case (pun intended here).... I have some relatively basic "case" code that should be looking at the cell value of A6 and hiding columns based on which month is showing. I'm having a hard time figuring out why it's skipping over the correct case (in this instance "May"). I can step through the code, but it is not stopping to perform the hide columns part. It just keeps going, checking each case and eventually hits the end of the sub and ends. I don't receive any errors, it just doesn't catch the correct value and perform the action. Any help would be appreciated. Thanks!

Answer 1

If score is a string such as January then score = "January" (etc) will return True (or False). True (or False) won't be equal to the value of score (i.e. "January"), so therefore none of your tests will be satisfied.
You probably meant to say:
Dim score As Variant
score = Range("KPI!A6").Value
Select Case score
Case "January"
Columns("D:N").EntireColumn.Hidden = True
Case "February"
Columns("C:C,E:N").EntireColumn.Hidden = True
Case "March"
Columns("C:D,F:N").EntireColumn.Hidden = True
Case "April"
Columns("C:E,G:N").EntireColumn.Hidden = True
Case "May"
Columns("C:F,H:N").EntireColumn.Hidden = True
Case "June"
Columns("C:G,I:N").EntireColumn.Hidden = True
Case "July"
Columns("C:H,J:N").EntireColumn.Hidden = True
Case "August"
Columns("C:I,K:N").EntireColumn.Hidden = True
Case "September"
Columns("C:J,L:N").EntireColumn.Hidden = True
Case "October"
Columns("C:K,M:N").EntireColumn.Hidden = True
Case "November"
Columns("C:L,N:N").EntireColumn.Hidden = True
Case "December"
Columns("C:M").EntireColumn.Hidden = True
End Select
End Sub
which will compare the value of score to each of the literal strings "January", "February", etc, in turn and execute the first Case where the comparison is True.
Or, as Jeeped suggests, to avoid removing score = from each of your Case statements you could use:
Dim score As Variant
score = Range("KPI!A6").Value
Select Case True
Case score = "January"
Columns("D:N").EntireColumn.Hidden = True
Case score = "February"
Columns("C:C,E:N").EntireColumn.Hidden = True
Case score = "March"
Columns("C:D,F:N").EntireColumn.Hidden = True
Case score = "April"
Columns("C:E,G:N").EntireColumn.Hidden = True
Case score = "May"
Columns("C:F,H:N").EntireColumn.Hidden = True
Case score = "June"
Columns("C:G,I:N").EntireColumn.Hidden = True
Case score = "July"
Columns("C:H,J:N").EntireColumn.Hidden = True
Case score = "August"
Columns("C:I,K:N").EntireColumn.Hidden = True
Case score = "September"
Columns("C:J,L:N").EntireColumn.Hidden = True
Case score = "October"
Columns("C:K,M:N").EntireColumn.Hidden = True
Case score = "November"
Columns("C:L,N:N").EntireColumn.Hidden = True
Case score = "December"
Columns("C:M").EntireColumn.Hidden = True
End Select
End Sub
which will compare the value True to each of the logical expressions such as score = January, score = February, etc, in turn and execute the first Case where the comparison to True returns True.
The Select Case statement is just a prettied-up If statement. The following Select Case statement
Select Case x
Case y
DoSomething
Case z
DoSomethingElse
End Select
is equivalent to the following If statement
If x = y Then
DoSomething
ElseIf x = z Then
DoSomethingElse
End If

Answer 2

No need to do the Select Case:
Dim score As Variant
With Worksheets("KPI")
score = .Range("A6").Value
'if score is a date remove this next line
score = DateValue(1 & " " & score & " 2017")
.Columns("C:N").Hidden = True
.Columns(Month(score) + 2).Hidden = False
End With