How do I have names of groups in columns and summarize values? - sql

Question

Sorry, not sure how to best word this so I'll just give an example.
1 VA b x 10
2 VA g y 5
3 VA b x 6
4 VA s y 7
5 VA s x 8
6 PA b y 1
7 PA s x 4
8 PA g y 5
9 PA s x 6
10 PA b y 9
I would like to summarize the above data like the following:
x_b x_s x_g y_b y_s y_g
VA 16 8 0 9 7 0
PA 0 10 0 9 0 5
where I have a row for each state and combinations of the two groups (group of x, y and group of b,s,g) across the top and summarize the values for all groupings like that.
What is the best way to do this in SQL?
Thanks!

Answer 1

You can do this using conditional aggregation:
proc sql;
select state,
sum(case when col3 = 'b' and col4 = 'x' then col5 else 0 end) as x_b,
sum(case when col3 = 's' and col4 = 'x' then col5 else 0 end) as x_s,
sum(case when col3 = 'g' and col4 = 'x' then col5 else 0 end) as x_g,
sum(case when col3 = 's' and col4 = 'y' then col5 else 0 end) as y_s,
sum(case when col3 = 'g' and col4 = 'y' then col5 else 0 end) as y_g
from t
group by state;

Answer 2

Don't do this in SQL. You're in SAS, use the tools you have: here PROC TABULATE is the best tool.
data have;
input obs state $ var1 $ var2 $ val;
datalines;
1 VA b x 10
2 VA g y 5
3 VA b x 6
4 VA s y 7
5 VA s x 8
6 PA b y 1
7 PA s x 4
8 PA g y 5
9 PA s x 6
10 PA b y 9
;;;;
run;
proc tabulate data=have;
class state var1 var2;
var val;
tables state, var1=' '*var2=' '*val=' '*sum=' '/printmiss misstext='0';
run;
If you want a dataset and not a printed table, that's easy enough to do. Just make a dataset from TABULATE, then make a few minor changes and transpose it.
proc tabulate data=have out=want_first;
class state var1 var2;
var val;
tables state, var1=' '*var2=' '*val=' '*sum=' '/printmiss misstext='0';
run;
data want_pret;
set want_first;
var_name = catx('_',var2,var1);
value = coalesce(val_sum,0);
keep state var_name value;
run;
proc transpose data=want_pret out=want;
by state;
id var_name;
var value;
run;
Notice that none of this requires hardcoding the values for any of the variables - no matter what you put in var1/var2, this will always give you the right result.

Answer 3

If you want to make a cross-tab use PROC FREQ. Use the WEIGHT statement to pass in the exiting counts and the SPARSE option to get the zeros output.
proc freq data=have ;
tables state*v2*v1 / noprint out=counts sparse ;
weight cnt ;
run;
You can then turn the result into your horizontal format by using PROC TRANSPOSE.
proc transpose data=counts delimiter=_
out=want(drop= _name_ _label_)
;
by state ;
id v2 v1 ;
var count ;
run;