Deleting rows in Excel based on Dictionary value in Excel VBA - vba

Question

I am still getting into VBA and currently I am trying to do the following:
- Delete rows in an Excel sheet based on a value stored in a dictionary.
I have this code:
For Each Key In dict.Keys
i = Key
Cells.Rows(i).Delete
Next
where before that I have populated the dictionary. The idea is that the "key" stores all the row number in which a specific value is stored, for example "1".
With the for each I want to delete all the rows stored in the dictionary, but once you delete a row in Excel the number changes. For example the first stored value in the dictionary is 5, so the for each will delete row number 5. The second value in the dictionary is 10 and now when the for each tries to delete row 10, it delete row 10, which in the original file used to be row 11. Basically the for each fails to delete the correct rows.
As I said I am new to VBA and I am not even sure if this is the correct way to do this or there is something better than dictionaries for this situation. I am looking forward to hearing your ideas and suggestions.
Thank you in advance!
Update: Solved by Ambie and sktneer. Check answers.

Answer 1

You may try something like this...
Dim rng As Range
Dim it
For Each it In dict.keys
If rng Is Nothing Then
Set rng = Range("A" & it)
Else
Set rng = Union(rng, Range("A" & it))
End If
Next it
If Not rng Is Nothing Then
rng.EntireRow.Delete
End If
End Sub

Answer 2

I'm not sure I'd bother with the Dictionary. Afterall, a Range is a collection, so perhaps just consider putting all of your target rows into a range and run the 'bulk' delete on that range. It'd be far quicker than a delete by looping rows:
Dim delRng As Range, srcRng As Range, cell As Range
'Loop through the range containing your criterion test
With Sheet1
Set srcRng = .Range(.Cells(1, "A"), .Cells(.Rows.Count, "A").End(xlUp))
End With
For Each cell In srcRng.Cells
If cell.Value2 = 1 Then 'change to your criterion
'It's a hit so add the cell to our delete range
If delRng Is Nothing Then
Set delRng = cell
Else
Set delRng = Union(delRng, cell)
End If
End If
Next
'Delete the rows
If Not delRng Is Nothing Then delRng.EntireRow.Delete