Using awk to split a record into multiple fields - awk

Question

I have a file with records which are not separated by any delimiter . A sample is shared below:
XXXXXYYYYZZZ
XXXXXYYYYZZZ
XXXXXYYYYZZZ
XXXXXYYYYZZZ
XXXXXYYYYZZZ
I have been given a DDL for the file such that field 1 lies in the position 1-5, field 2 lies in the position 6-9 , field 3 lies in the position 10-12
How to use awk command to print the below output?
field1,field2,field3
XXXXX,YYYY,ZZZ
XXXXX,YYYY,ZZZ
XXXXX,YYYY,ZZZ
XXXXX,YYYY,ZZZ
XXXXX,YYYY,ZZZ

Answer 1

IN GNU awk using FIELDWIDTHS:
$ awk '
BEGIN {
FIELDWIDTHS="5 4 3" # here you state the field widths
OFS="," # output field separator
print "field1","field2","field3" } # print header in BEGIN
{
print $1,$2,$3 } # print 3 first fields, you could also:
' file # {$1=$1; print} or even:
field1,field2,field3 # {$1=$1}1
XXXXX,YYYY,ZZZ
XXXXX,YYYY,ZZZ
XXXXX,YYYY,ZZZ
XXXXX,YYYY,ZZZ
XXXXX,YYYY,ZZZ
If you don't have GNU awk, use f1=substr($0,1,5);f2=substr($0,6,4)...print f1,f2,f3.
Edit:
$ awk '
BEGIN {
OFS=","
print "field1","field2","field3" }
{
f1=substr($0,1,5)
f2=substr($0,6,4)
f3=substr($0,10,3)
print f1,f2,f3 }
' file
Latter as one-liner with ;s inserted:
$ awk 'BEGIN {OFS=","; print "field1","field2","field3"}{f1=substr($0,1,5); f2=substr($0,6,4); f3=substr($0,10,3); print f1,f2,f3}' file
The former as one-liner:
$ awk 'BEGIN{FIELDWIDTHS="5 4 3"; OFS=","; print "field1","field2","field3"}{print $1,$2,$3}' file

Answer 2

This might work for you (GNU sed):
sed -e '1i\field1,field2,field3' -e 's/[^,]/,&/6;s//,&/10' file

Answer 3

without using substr(), here's a not-so-elegant awk way to get around it
echo 'XXXXXYYYYZZZ
XXXXXYYYYZZZ
XXXXXYYYYZZZ
XXXXXYYYYZZZ
XXXXXYYYYZZZ' |
mawk 'BEGIN { OFS = ","
print (__ = "field")(++_), (__)(++_), (__)(++_)
_ = (_ = (_ = ".")_)_
__ = "&,"
} sub("." _,__) + sub("," _,__)^_'
field1,field2,field3
XXXXX,YYYY,ZZZ
XXXXX,YYYY,ZZZ
XXXXX,YYYY,ZZZ
XXXXX,YYYY,ZZZ
XXXXX,YYYY,ZZZ