How to export identified values to a new sheet? - vba

Question

This is a follow up to my previous question that can be found here
Just for a quick recap, I have this table:
ID Age Grade
1 14 90
2 15 78
3 14 90
4 16 86
5 16 86
6 15 89
7 14 88
My desired output table in a new sheet is:
ID Age Grade
1 14 90
3 14 90
4 16 86
5 16 86
I went through and picked out the rows that have repeating values in column B AND column C using this:
Sub Export()
Dim lastRowcheck As Long, n1 As Long
With Worksheets("Sheet1")
lastRowcheck = Application.Max(.Range("B" & .Rows.Count).End(xlUp).Row, _
.Range("C" & .Rows.Count).End(xlUp).Row)
For n1 = lastRowcheck To 1 Step -1
If Application.CountIfs(.Columns("B"), .Cells(n1, "B").Value2, .Columns("C"), .Cells(n1, "C").Value2) > 1 Then
Debug.Print .Cells(n1, "A") & ":" & .Cells(n1, "B") & ":" & .Cells(n1, "C")
'''export to new sheet
End If
Next n1
End With
End Sub
Now I just need to figure out how to export those rows into a new sheet and I have no idea where to start.

Answer 1

Updated your code to show how to export the found rows to a new sheet:
Sub Export()
Dim lastRowcheck As Long, n1 As Long
Dim rCopy As Range
With Worksheets("Sheet1")
lastRowcheck = Application.Max(.Range("B" & .Rows.Count).End(xlUp).Row, _
.Range("C" & .Rows.Count).End(xlUp).Row)
For n1 = lastRowcheck To 1 Step -1
If Application.CountIfs(.Columns("B"), .Cells(n1, "B").Value2, .Columns("C"), .Cells(n1, "C").Value2) > 1 Then
Debug.Print .Cells(n1, "A") & ":" & .Cells(n1, "B") & ":" & .Cells(n1, "C")
'''export to new sheet
If rCopy Is Nothing Then Set rCopy = .Rows(n1) Else Set rCopy = Union(rCopy, .Rows(n1))
End If
Next n1
End With
With Sheets("Sheet2") 'For using a sheet that already exists
'With Sheets.Add(After:=Sheets(Sheets.Count)) 'For creating a brand new sheet to use
If Not rCopy Is Nothing Then rCopy.EntireRow.Copy _
Destination:=.Cells(.Rows.Count, "A").End(xlUp).Offset(1)
End With
End Sub

Answer 2

Why you are using loop in descending order
For n1 = lastRowcheck To 1 Step -1
For n1 = 1 To lastRowcheck
while you can use it if you need result in same order as per data.
Sub Export()
Dim lastRowcheck As Long, n1 As Long, i As Long
Dim ws As Worksheet
Set ws = Sheets("NewSheet") 'sheet name to export data
i = 2 'add data from row 2 in new sheet
With Worksheets("Sheet1")
lastRowcheck = Application.Max(.Range("B" & .Rows.Count).End(xlUp).Row, _
.Range("C" & .Rows.Count).End(xlUp).Row)
For n1 = 1 To lastRowcheck
If Application.CountIfs(.Columns("B"), .Cells(n1, "B").Value2, .Columns("C"), .Cells(n1, "C").Value2) > 1 Then
Debug.Print .Cells(n1, "A") & ":" & .Cells(n1, "B") & ":" & .Cells(n1, "C")
'''export to new sheet
ws.Cells(i, "A") = .Cells(n1, "A")
ws.Cells(i, "B") = .Cells(n1, "B")
ws.Cells(i, "C") = .Cells(n1, "C")
i = i + 1
End If
Next n1
End With
End Sub