Select Entire Sheets for Printing: Excel VBA - vba

Question

I created a VBA macro to export specific sheets of a workbook to a PDF. Simple enough. The problem that I am experiencing is that my code only selects part of Sheet4, so in my PDF part of the sheet is missing.
Sheet4 contains data in range A1:W80. However, when running the code below only the range A1:W75 is selected for printing. I have confirmed my PrintArea contains the entire page. Everything even looks great when printing.
I have searched endlessly for a solution, with no success. Could this be a page-layout setting issue? How can I ensure I am selecting the entire sheet, instead of only part of it, when exporting to PDF?
Here is my code:
Sub SaveReportPDF()
Dim filepath As String
filepath = "ABC"
ThisWorkbook.Sheets(Array("Sheet1", "Sheet2", "Sheet3", "Sheet4")).Select
Selection.ExportAsFixedFormat _
Type:=xlTypePDF, _
Filename:=filepath, _
Quality:=xlQualityStandard, _
IncludeDocProperties:=True, _
IgnorePrintAreas:=False, _
OpenAfterPublish:=False
End Sub

Answer 1

As good practise, you can set your used range of each sheet as the print area, and fit it to the page, using the following sub:
Sub ScaleForPrinting()
Dim sh As Worksheet
' Stop PrintCommunication for speed
Application.PrintCommunication = False
' Cycle through each sheet
For Each sh In ThisWorkbook.Sheets(Array("Sheet1", "Sheet2", "Sheet3", "Sheet4"))
' Set print area to used range of sheet
sh.PageSetup.PrintArea = sh.UsedRange
' Remove zoom, scale sheet to fit 1 page
With sh.PageSetup
.CenterHorizontally = True
.CenterVertically = True
.Zoom = False
.FitToPagesWide = 1
.FitToPagesTall = 1
End With
Next sh
' Enable PrintCommunication to apply settings
Application.PrintCommunication = True
End Sub
Then you will want to use the ActiveSheet object after selecting, rather than the Selection object. This is perhaps counter-intuitive, but you want to print the sheets not what you've selected in the sheets.
So:
ScaleForPrinting
ThisWorkbook.Sheets(Array("Sheet1", "Sheet2", "Sheet3", "Sheet4")).Select
ActiveSheet.ExportAsFixedFormat _
Type:=xlTypePDF, _
Filename:=filepath, _
Quality:=xlQualityStandard, _
IncludeDocProperties:=True, _
IgnorePrintAreas:=False, _
OpenAfterPublish:=False
' Deselect sheets to avoid nasty multiple sheet accidental editing!
ThisWorkbook.Sheets("Sheet1").Select