Cannot figure out why VBA code is not entering the If statement - vba

Question

I am trying to sort through accounts in two separate worksheets ("Participaciones Bond" and "Participaciones VAL") and copy the customers that are in both sheets into one column in worksheet "resumen" and the customers that are in one, but not the other, into another column in "resumen".
The part that copies those customers in both sheets works well, but I cannot figure out why the second if statement does not work.
'Patribond= i, patriVal= j
i = 5
j = 5
Do While Worksheets("Participaciones Bond ").Cells(i, "A") <> ""
j = 5
Do While Worksheets("Participaciones VAL ").Cells(j, "A") <> ""
If Worksheets("Participaciones Bond ").Cells(i, 1).Value = Worksheets("Participaciones VAL ").Cells(j, 1).Value Then
Worksheets("Participaciones Bond ").Activate
Sheets("Participaciones Bond ").Select
Worksheets("Participaciones Bond ").Rows(i).Copy Sheets("Resumen").Range("A1048576").End(xlUp).Offset(1, 0)
Exit Do
End If
j = j + 1
'personas en patribond que no aparecen en patrival'
If Worksheets("Participaciones VAL ").Cells(j, 1) = "" Then
Worksheets("Resumen").Activate
'Cells(3, "H").Value = "We got into the second IF"'
Worksheets("Participaciones Bond ").Activate
Range(Cells(i, "A"), Cells(i, "E")).Copy
Worksheets("Resumen").Activate
Range(Cells(i, "G"), Cells(i, "X")).Select
Worksheets("Resumen").Paste
End If
Loop
i = i + 1
Loop

Answer 1

I don't know which data you have for testing, but I think that your code is working just fine, that is: it is entering both If conditions. But the way you check it is by writing into a cell ("H3") that is probabily overwritten when you copy an entire row with the instruction
with Worksheets("Participaciones Bond ").Rows(i).Copy Sheets("Resumen").Range("A1048576").End(xlUp).Offset(1, 0)
This is how I would do it.
You don't need to change selection nor to activate worksheets in order to copy from / to them.
Also, I would copy in the same way both times, for records in both sheets and for records only in the first sheet, not copying the entire row, but limiting the source to the range containing the data. This way you won't accidentally overwrite the columns to the right of the sheet. And your records will get copied at the top of the "Resumen" sheet, too.
In order to do so, I changed
Rows(i).Copy.
to
Range("A" & i, "E" & i).Copy.
I also added references to the three sheets though it isn't necessary.
Dim wBond As Worksheet
Dim wVal As Worksheet
Dim wRes As Worksheet
Set wBond = Worksheets("Participaciones Bond ")
Set wVal = Worksheets("Participaciones Val ")
Set wRes = Worksheets("Resumen")
i = 5
Do While Not IsEmpty(wBond.Cells(i, "A"))
j = 5
Do While Not IsEmpty(wVal.Cells(j, "A"))
If wBond.Cells(i, 1).Value = wVal.Cells(j, 1).Value Then
' La persona está en ambas hojas: copiar en la columna correspondiente
wBond.Range("A" & i, "E" & i).Copy wRes.Cells(Rows.Count, "A").End(xlUp).Offset(1, 0)
Exit Do
End If
j = j + 1
If IsEmpty(wVal.Cells(j, 1)) Then
wBond.Range("A" & i, "E" & i).Copy wRes.Cells(Rows.Count, "G").End(xlUp).Offset(1, 0)
End If
Loop
i = i + 1
Loop

Answer 2

I started writing this code before dinner and got stuck. Now I am well fed but the thread may have progressed beyond what I was doing. Basically, I went by your description and wrote my own code. It's a different approach from the one you took, but then I got stuck on the meaning of your second IF and couldn't figure it out. Please run my code on your data and tell me if its worth continuing.
The code runs through all your names on the Bond sheet and copies data to the Resumen sheet. If a duplicate is found in the Val sheet it copies 10 columns of the Val data (I wonder, is this a logical error) to column A, else it copies 10 columns of data from the Bond sheet (I think both are the same and therefore I would prefer to copy all from the Bond sheet) to column K. The code is simpler than yours and therefore easier to tweak. Take a look. Test it on your data and see what you get.
Sub CopyCustomers()
' 06 Apr 2017
Dim WsBond As Worksheet
Dim WsVal As Worksheet
Dim WsRes As Worksheet
Dim Rl As Long ' WsBond last row
Dim R As Long ' WsBond row
Dim Rv As Long ' found row in WsVal
Dim Rr As Long ' next row in WsRes
Dim Cr As Long ' column in WsRes
Dim Cust As String ' customer name from WsBond
Dim Rng As Range ' range to be copied to WsRes
Set WsBond = Sheets("Participaciones Bond ")
Set WsVal = Sheets("Participaciones VAL ")
Set WsRes = Sheets("Resumen")
Rr = 5
Application.EnableEvents = False
With WsBond
Rl = .Cells(.Rows.Count, 1).End(xlUp).Row
For R = 5 To Rl
Cust = .Cells(R, 1).Value
Rv = 0
On Error Resume Next
Rv = WorksheetFunction.Match(Cust, WsVal.Columns(1), 0)
' no need to copy the entire row of 140K cells (takes too much time)
' in each of the following rows 10 stands for 10 columns being copied
If Err = 0 Then
Set Rng = WsVal.Range(WsVal.Cells(Rv, 1), WsVal.Cells(Rv, 10))
Cr = 1 ' paste to column A
Else
Set Rng = .Range(.Cells(R, 1), .Cells(R, 10))
Cr = 11 ' paste to column K
End If
Rng.Copy Destination:=WsRes.Cells(Rr, Cr).Resize(1, 10)
Rr = Rr + 1
Err.Clear
Next R
End With
Application.EnableEvents = True
End Sub
There might be names in the Val sheet which are not in the Bond sheet. They would be easy to add but that would take another loop, not another IF. You might also not like the arrangement of rows in the Resumen sheet. Easy to tweak. I suppose you might be able to do it yourself. You don't want 10 column, you don't want column A, you don't agree with column K - all easy to adjust. I will be glad to help if you need help.

Answer 3

assuming your data have headers in row 4, you could exploit Autofilter() and go like follows
Option Explicit
Sub main()
Dim commonRng As Range, uniqueBondRng As Range, uniqueValRng As Range
GetCommonAndUniqueData "Participaciones Bond", "Participaciones VAL", commonRng, uniqueBondRng
GetCommonAndUniqueData "Participaciones VAL", "Participaciones Bond", commonRng, uniqueValRng
If Not commonRng Is Nothing Then commonRng.Copy Worksheets("Resumen").Range("a1")
If Not uniqueBondRng Is Nothing Then uniqueBondRng.Copy Worksheets("Resumen").Range("B1")
If Not uniqueValRng Is Nothing Then uniqueValRng.Copy Worksheets("Resumen").Range("C1")
End Sub
Sub GetCommonAndUniqueData(sht1Name As String, sht2Name As String, commonRng As Range, uniqueRng As Range)
Dim cell As Range
With Worksheets(sht1Name)
With .Range("A4", .Cells(.Rows.Count, 1).End(xlUp))
.AutoFilter Field:=1, Criteria1:=GetValues(sht2Name), Operator:=xlFilterValues
With .Offset(1).Resize(.Rows.Count - 1)
If Application.WorksheetFunction.Subtotal(103, .Cells) > 0 Then Set commonRng = .SpecialCells(xlCellTypeVisible)
.Parent.AutoFilterMode = False
If commonRng Is Nothing Then
Set uniqueRng = .Cells
Else
Set uniqueRng = .Cells(.Rows.Count + 1, 1).Resize(1)
For Each cell In .Cells
If Intersect(commonRng, cell) Is Nothing Then Set uniqueRng = Union(uniqueRng, cell)
Next
Set uniqueRng = Intersect(uniqueRng, .Cells)
End If
End With
End With
End With
End Sub
Function GetValues(shtName As String) As Variant
With Worksheets(shtName)
GetValues = Application.Transpose(.Range("A5", .Cells(.Rows.Count, 1).End(xlUp)).Value)
End With
End Function