VBA code for comparing first column of multiple spreadsheet with mastersheet - vba

Question

I have VBA code for comparing first column and highlight the cell in first column of sheet2 which is not there in sheet1.
I am new to VBA and not good in coding part and need this to work in a excel sheet which has multiple spreadsheet(This may vary from 5 to 10).
sheet1 is the master sheet and other sheet should be compared with the master sheet and highlight the cell which is not present in master sheet.
Public Sub CompareSheets()
Dim ws1 As Worksheet, ws2 As Worksheet
Dim cell As Range, rng As Range
Set ws1 = Worksheets("Sheet1")
Set ws2 = Worksheets("Sheet2")
Set rng = ws1.Range("A1:A20")
For Each cell In rng
Celladdress = cell.Address
If cell <> ws2.Range(Celladdress) Then
cell.Interior.Color = vbYellow
ws2.Range(Celladdress).Interior.Color = vbYellow
End If
Next cell
End Sub

Answer 1

This code avoids a row-by-row comparison (per your comments) and looks for each value in column A of Sheet2, Sheet3, Sheet4, etc to be found somewhere in column A of Sheet1. It also locates rows that are greater than the total number of rows with values in Sheet1.
This does not force the cells to vbYellow. Instead, it uses conditional formatting to show vbYellow on non-matching cells. These can be filtered for just as forced vbYellow cells can. The benefit here is that once a value has been corrected (a match to Sheet1!A:A is made), the highlight will be auto-magically removed.
Option Explicit
Sub CompareSheets()
Dim lrw1 As Long, lrwn As Long, w As Long
'get the last row of values in master sheet
With Worksheets(1)
lrw1 = .Cells(.Rows.Count, "A").End(xlUp).Row
End With
'the first worksheet (e.g. worksheets(1) ) is the 'master sheet' so we start at 2
For w = 2 To Worksheets.Count
With Worksheets(w)
lrwn = .Cells(.Rows.Count, "A").End(xlUp).Row
With .Range(.Cells(1, "A"), .Cells(Application.Max(lrwn, lrwn), "A"))
.FormatConditions.Delete
With .FormatConditions.Add(Type:=xlExpression, _
Formula1:="=OR(ROW()>" & lrw1 & ", ISNA(MATCH($A1, " & Worksheets(1).Columns("A").Address(external:=True) & ", 0)))")
With .Interior
.PatternColorIndex = xlAutomatic
.Color = vbYellow
End With
.StopIfTrue = True
End With
End With
End With
Next w
End Sub
FWIW, I found your narrative a bit confusing. It either contradicted the supplied code or contradicted itself. The logic behind this proposed solution comes largely from your comments.