The OpenForm was cancelled error has reoccurred - vba

Question

The OpenForm has reoccurred in my application. I have decompiled/compact and repaired twice.
Code throwing error:
'Open Menu form
DoCmd.OpenForm "Menu", acNormal, , , , acWindowNormal
The first time I encountered this error, I solved it by changing:
DoCmd.OpenForm "Menu", acNormal, "", "", , acNormal
to
DoCmd.OpenForm "Menu", acNormal, , , , acWindowNormal.
This is my procedure that suffers the exception:
Private Sub Login(recordSet As DAO.recordSet, PERSAL As String, Password As String)
On Error GoTo Login_ErrHandler
'Check to see if the recordset actually contains rows
If Not (recordSet.EOF And recordSet.BOF) Then
recordSet.MoveFirst 'Unnecessary in this case, but still a good habit
'See if credentials match data
Do
If (recordSet!User_ID = PERSAL And recordSet!Password = Password) Then
'Open Menu form
DoCmd.OpenForm "Menu"
' Form_Menu.op
recordSet.Close 'Close the recordset
Set recordSet = Nothing 'Clean up
'Close Login form
DoCmd.Close acForm, "Login"
Exit Do
End If
recordSet.MoveNext
If (recordSet.EOF Or recordSet.BOF) Then
MsgBox "Your credentials are incorrect or you are not registered."
Exit Do
End If
Loop
'Match the values entered for PERSAL nr. and password fields with a row in User table
Else
MsgBox "There are no records in the recordset."
recordSet.Close 'Close the recordset
Set recordSet = Nothing 'Clean up
End If
Form_Login.txtUser_ID.SetFocus
Login_ErrHandler:
If Err = 2501 Then
'MsgBox "No data to display"
DoCmd.Hourglass False
Resume Login_ErrHandler
' Else
' MsgBox Err.Description, vbCritical
End If
End Sub
How do I fix this error this time around?

Answer 1

Create a parameterized query with the following SQL:
PARAMETERS [prmUserId] Text ( 255 ), [prmPassword] Text ( 255 );
SELECT User_ID, Password
FROM YOUR_TABLE_NAME
WHERE ((([User_ID])=[prmUserId]) AND (([Password])=[prmPassword]));
Assuming the code is behind the Login Form:
Private Sub Login(ByVal PERSAL As String, ByVal Password As String)
On Error GoTo Login_ErrHandler
Dim qdf As DAO.QueryDef
Set qdf = CurrentDb().QueryDefs("YourQueryName") 'Change to your query name
qdf.Parameters("[prmUserId]").Value = PERSAL
qdf.Parameters("[prmPassword]").Value = Password
Dim rs As DAO.recordSet
Set rs = qdf.OpenRecordset()
'No records
If rs.EOF Then
MsgBox "Your credentials are incorrect or you are not registered."
Me.txtUser_ID.SetFocus
GoTo Leave
End If
'User found
'Close Login Form
DoCmd.Close acForm, Me.Name, acSavePrompt
'Open Form
DoCmd.OpenForm "Menu", acNormal, , , acFormPropertySettings, acWindowNormal
Leave:
On Error Resume Next
rs.Close
Set rs = Nothing
qdf.Close
Set qdf = Nothing
On Error GoTo 0
Exit Sub
Login_ErrHandler:
MsgBox Err.Number & " - " & Err.Description, vbCritical
Resume Leave
End Sub