SAS update multiple records for a by group - sql

Question

I have a master A and transaction set B. I am trying to udpate records in A with the records in B by variable C.
DATA TEST;
UPDATE A B;
BY C;
RUN;
The issue is, I have got some duplicate records in my master set and I still want to update them all. But what I get is a warning
There was more than one record for the specified BY group
And only the first record out of those duplicates gets updated.
Is there any way how to tell SAS to update all of them?
Or is there any other, completely different way?
Any help appreciated.

Answer 1

If you create an index on the ID variable used for your update, you can do this using a modify statement. This should be much quicker than using an update statement as it avoids creating a temporary copy of the master table - however, if the data step is interrupted there is a risk of data corruption. The syntax is a bit clunky but it can potentially be macro-ised if necessary.
data master;
input ID1 ID2 VAR1 VAR2;
cards;
1 1 2 3
1 2 3 4
2 1 5 6
;
run;
data transaction;
input ID1 VAR1 VAR2;
cards;
1 7 8
;
run;
proc datasets lib =work nolist nodetails;
modify master;
index create ID1;
quit;
data master;
set transaction(rename = (VAR1 = t_VAR1 VAR2 = t_VAR2));
do until(eof);
modify master key = ID1 end = eof;
if _IORC_ then _ERROR_ = 0;
else do;
VAR1 = t_VAR1;
VAR2 = t_VAR2;
replace;
end;
end;
drop t_VAR1 t_VAR2;
run;

Answer 2

If you really want to apply transactions then expand your transaction file to have all possible values of the key variables C,D for the values of C it does contain.
proc sql ;
create table transactions as
select a.D,b.*
from A right join B
on a.C = b.C
order by b.C,a.D
;
quit;
Then do the update.
data want ;
update A transactions ;
id c d;
run;
If you try to use MERGE then you will get in trouble when the extra variables exist in both tables. SAS will only change the values of the first record for each value of C. You could program around this by renaming the variables in the B dataset. You could then explicitly code whether you want the action to be like a MERGE or an UPDATE. So if your extra variable is named E then you could code like this:
data want;
merge a b(in=inb rename=(e=new_e)) ;
by c ;
updated_e = coalesce(new_e,e);
if inb then merged_e = new_e ;
else merged_e = e;
run;
So if you want the effect of merge (so a missing value of E in the transaction makes it missing the result) then use the formula like in MERGED_E. If you want the effect of update then use the formula like in UPDATED_E. If you have more than one extra variable then rename them also and add extra assignment statements to handle them.