Trigger — is invalid and failed re-validation - sql

Question

I am trying to create this simple trigger :
CREATE OR REPLACE TRIGGER my_trig
BEFORE DELETE OR INSERT OR UPDATE ON empcopy
FOR EACH ROW
WHEN (NEW.EID > 0)
DECLARE
sal_diff number;
BEGIN
sal_diff := :NEW.salary - :OLD.salary;
dbms_output.put_line('Old salary: ' || :OLD.salary);
dbms_output.put_line('New salary: ' || :NEW.salary);
dbms_output.put_line('Salary difference: ' || sal_diff);
COMMIT;
END;
/
on execution it gives the result as:
Trigger created
But when I update my table the following result is obtained:
update empcopy
set salary=salary+5000;
after execution:
error at line 1
ORA-0498:triiger 'HR.MY_TRIG' is invalid and failed re-validation.

Answer 1

You can't COMMIT without using a PRAGMA AUTONOMOUS_TRANSACTION in your DECLARE block.
If the database allowed committing in row-level triggers, this could enable committing part of the rows in a statement before the others had been evaluated and would disrupt the statement as a unit--all rows in an individual statement should complete their change and be committed together.
If you were to use an AUTONOMOUS_TRANSACTION in this trigger, this would allow the trigger to execute new UPDATEs, DELETEs, etc in a transaction independent from other active DML changes in the open transaction.
But note, in you're case, your TRIGGER isn't actually executing any mutational DML, nor even any reads, so you don't need a COMMIT at all. All you need to do is drop your COMMIT as below.
CREATE OR REPLACE TRIGGER my_trig
BEFORE DELETE OR INSERT OR UPDATE ON empcopy
FOR EACH ROW
WHEN (NEW.EID > 0)
DECLARE
sal_diff number;
BEGIN
sal_diff := :NEW.salary - :OLD.salary;
dbms_output.put_line('Old salary: ' || :OLD.salary);
dbms_output.put_line('New salary: ' || :NEW.salary);
dbms_output.put_line('Salary difference: ' || sal_diff);
END;
/
I would however suggest a couple other changes as well.
As other triggers can also change the NEW value, you might consider making this an AFTER TRIGGER, to only log the final state.
Also this trigger will not log any DELETEs, since DELETEs will all have a NULL :NEW.EID. I'd suggest either dropping the AFTER DELETE if logging DELETEs is not intended, or handling DELETEs separately via a CASE WHEN DELETING statement.
CREATE OR REPLACE TRIGGER MY_TRIG
AFTER DELETE OR INSERT OR UPDATE ON EMPCOPY
FOR EACH ROW
DECLARE
SAL_DIFF NUMBER;
BEGIN
CASE WHEN DELETING
THEN
DBMS_OUTPUT.put_line('Log the delete here if you want.');
WHEN (:NEW.EID > 0)
THEN
SAL_DIFF := COALESCE(:NEW.SALARY, 0) - COALESCE(:OLD.SALARY, 0);
DBMS_OUTPUT.put_line('Old salary: ' || :OLD.SALARY);
DBMS_OUTPUT.put_line('New salary: ' || :NEW.SALARY);
DBMS_OUTPUT.put_line('Salary difference: ' || SAL_DIFF);
ELSE NULL;
END CASE;
END;
/
Also DBMS_OUTPUT is transient logging. In case you want to keep a record of changes to EMPCOPY more permanently, Oracle has tools available to automate and control change-tracking in your data, such as audit trail and FGA.
EDIT: examples below.
Create a test table:
CREATE TABLE EMPCOPY(
EID NUMBER NOT NULL,
SALARY NUMBER
);
Table EMPCOPY created.
Then create the trigger:
CREATE OR REPLACE TRIGGER MY_TRIG
AFTER DELETE OR INSERT OR UPDATE ON EMPCOPY
FOR EACH ROW
DECLARE
SAL_DIFF NUMBER;
BEGIN
CASE WHEN DELETING
THEN
DBMS_OUTPUT.put_line('Log the delete here if you want.');
WHEN (:NEW.EID > 0)
THEN
SAL_DIFF := COALESCE(:NEW.SALARY, 0) - COALESCE(:OLD.SALARY, 0);
DBMS_OUTPUT.put_line('Old salary: ' || :OLD.SALARY);
DBMS_OUTPUT.put_line('New salary: ' || :NEW.SALARY);
DBMS_OUTPUT.put_line('Salary difference: ' || SAL_DIFF);
ELSE NULL;
END CASE;
END;
/
Trigger MY_TRIG compiled
Then test it:
SQL> --Should not log, EMPID is not greater than zero.
SQL> INSERT INTO EMPCOPY VALUES (-13, 50000);
1 row inserted.
SQL> --Should log, EMPID is greater than zero.
SQL> INSERT INTO EMPCOPY VALUES (1919, 75000);
Old salary:
New salary: 75000
Salary difference: 75000
1 row inserted.
SQL> -- The statement you provided. This should log for EMPID=1919 but not EMPID=-13
SQL> update empcopy
2 set salary=salary+5000;
Old salary: 75000
New salary: 80000
Salary difference: 5000
2 rows updated.
SQL> -- This should log a PLACEHOLDER value for each row on delete.
SQL> DELETE FROM EMPCOPY;
Log the delete here if you want.
Log the delete here if you want.
2 rows deleted.