cast string to location - vb.net

Question

When I export a control's location to string, using the standard Control.Location.ToString method, I get the following:
{X=163,Y=196}
How can I turn this string back to location? Is there any out-of-the box function, or do I need to parse this string and do it myself?
Update:
I would like to serialize a few objects on the screen to XML to save progress and read it back later.

Answer 1

If you are serializing, then the serializer ought to handle the conversion from Point to string and back. If you examine the serializer output, it should look like this: 727, 97.
This form is InvariantString and NET provides the means to convert these without having to parse the text:
Dim pt = Button10.Location
Dim cvtr = TypeDescriptor.GetConverter(GetType(Point))
' convert Pt to invariant string
Dim strPT = cvtr.ConvertToInvariantString(pt)
Console.WriteLine(strPT)
' try to convert back
Dim pt2 = DirectCast(cvtr.ConvertFromInvariantString(strPT), Point)
If pt.Equals(pt2) Then
Console.Beep()
End If
Output:
727, 97
(Beep)
But again, a serializer should convert for you.
If you are doing lots of this, a generic version is handy:
Private Function CvtToInvariantString(Of T)(item As T) As String
Dim cvtr = TypeDescriptor.GetConverter(GetType(T))
Return cvtr.ConvertToInvariantString(item)
End Function
Private Function CvtFromInvariantString(Of T)(str As String) As T
Dim cvtr = TypeDescriptor.GetConverter(GetType(T))
Return DirectCast(cvtr.ConvertFromInvariantString(str), T)
End Function
Usage:
Dim strPT = CvtToInvariantString(pt)
Dim pt2 = CvtFromInvariantString(Of Point)(strPT)