Why does this "Is" test fail with this comparison? - vb.net

Question

I have this code to compare the value of two control tag values:
Protected Function GetLabelTextForTag(tagVal As String) As String
Dim CoName As String = ""
For Each cntrl As Control In Me.Controls
If TypeOf cntrl Is Label Then
If DirectCast(cntrl, Label).Tag Is tagVal Then
CoName = DirectCast(cntrl, Label).Text
Exit For
End If
End If
Next
Return CoName
End Function
Even when I get to this line, though:
If DirectCast(cntrl, Label).Tag Is tagVal Then
...and Tag is the same as tagVal ("1"), the next line is not reached - "1" is not seen as being the same thing as "1"
Not being familiar with VB, I thought maybe the "Is" was the problem. But the reason I used "IS" to begin with, though, is because when I first tried this:
If DirectCast(cntrl, Label).Tag = tagVal Then
...I got, "Error 1 Option Strict On disallows operands of type Object for operator '='. Use the 'Is' operator to test for object identity."
The function is called by an event handler for a button click:
Private Sub Button1_Click( sender As Object, e As EventArgs) Handles Button1.Click
Dim connStr As String = "SERVER=PLATYPUS42;DATABASE=duckbilldata;UID=durante;PWD=pondscum"
Dim upd8DML As String = "UPDATE CustomerCategoryLog SET Category = 'Exploding' WHERE Unit = #Unit And MemberNo = #MemberNo AND Custno = #CustNo"
Dim coName As String
Dim argVals(2) As String
Dim _Unit As String
Dim _MemberNo As String
Dim _CustNo As String
Dim curTagVal As String
For Each cntrl As Control In Me.Controls
If TypeOf cntrl Is CheckBox Then
If DirectCast(cntrl, CheckBox).Checked = True Then
curTagVal = CStr(DirectCast(cntrl, CheckBox).Tag)
coName = GetLabelTextForTag(curTagVal)
argVals = GetArgValsForCompanyName(coName)
_Unit = argVals(0)
_MemberNo = argVals(1)
_CustNo = argVals(2)
Using conn As New SqlConnection(connStr), _
cmd As New SqlCommand(upd8DML, conn)
cmd.Parameters.Add("#CoName", SqlDbType.VarChar, 50).Value = coName
conn.Open
cmd.ExecuteScalar()
End Using
End If
End If
Next
End Sub
I'm looking for labels and checkboxes with the same tag value, because I'm dynamically creating some pairs of these controls, and need to know which corresponding checkboxes are checked for which labels. I create them (a few, this is just a test) like so:
Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
Dim sqlConnection1 As New SqlConnection("SERVER=PLATYPUS42;DATABASE=duckbilldata;UID=durante;PWD=pondscum")
Dim cmd As New SqlCommand
Dim reader As SqlDataReader
cmd.CommandText = "select C.CompanyName from CustomerCategoryLog CCL join Customers C on C.CustNo = CCL.Custno where CCL.Category = 'New' and C.Active <> 0 order by C.CompanyName"
cmd.CommandType = CommandType.Text
cmd.Connection = sqlConnection1
sqlConnection1.Open()
reader = cmd.ExecuteReader()
' Data is accessible through the DataReader object here.
If reader.HasRows Then
Dim i As Integer = 0
While reader.Read()
i = i+1
If i > 12 'There are thousands...just grab the first dozen for this test
Exit While
End If
Dim lblCompanyName = New Label()
lblCompanyName.Tag = i.ToString() 'ID not available...?!?
lblCompanyName.Text = reader.Item(0).ToString()
Me.Controls.Add(lblCompanyName)
Dim ckbx = New CheckBox()
ckbx.Tag = i.ToString()
ckbx.Checked = True
Me.Controls.Add(ckbx)
End While
End If
reader.Close()
sqlConnection1.Close()
End Sub
I may as well add the only other bit of code on the form, too, for good measure:
Protected Function GetArgValsForCompanyName(coName As String) As String()
Dim args(2) As String
Dim sqlConnection1 As New SqlConnection("SERVER=PLATYPUS42;DATABASE=duckbilldata;UID=durante;PWD=pondscum")
Dim cmd As New SqlCommand
Dim reader As SqlDataReader
cmd.CommandText = "select Unit, MemberNo, CustNo from Customers WHERE CompanyName = #CoName"
cmd.CommandType = CommandType.Text
cmd.Parameters.Add("#CoName", SqlDbType.VarChar, 50).Value = coName
cmd.Connection = sqlConnection1
sqlConnection1.Open()
reader = cmd.ExecuteReader()
' Data is accessible through the DataReader object here.
If reader.HasRows Then
args(0) = reader.Item(0).ToString()
args(1) = reader.Item(1).ToString()
args(2) = reader.Item(2).ToString()
End If
reader.Close()
sqlConnection1.Close()
Return args
End Function
When is "1" not "1"?

Answer 1

Okay, Tag is an Object not a String hence with option strict on you get the issue, try
If DirectCast(cntrl, Label).Tag.ToString() = tagVal Then
Using Is you are comparing references not values.
Fixed this for you too
Private Sub Button1_Click( sender As Object, e As EventArgs) Handles Button1.Click
Dim connStr As String = "SERVER=PLATYPUS42;DATABASE=duckbilldata;UID=durante;PWD=pondscum"
Dim upd8DML As String = "UPDATE CustomerCategoryLog SET Category = 'Exploding' WHERE Unit = #Unit And MemberNo = #MemberNo AND Custno = #CustNo"
Dim coName As String
Dim argVals(2) As String
Dim _Unit As String
Dim _MemberNo As String
Dim _CustNo As String
Dim curTagVal As String
For Each cntrl As Control In Me.Controls
If TypeOf cntrl Is CheckBox Then
If DirectCast(cntrl, CheckBox).Checked = True Then
curTagVal = CStr(DirectCast(cntrl, CheckBox).Tag)
coName = GetLabelTextForTag(curTagVal)
argVals = GetArgValsForCompanyName(coName)
_Unit = argVals(0)
_MemberNo = argVals(1)
_CustNo = argVals(2)
Using conn As New SqlConnection(connStr), _
cmd As New SqlCommand(upd8DML, conn)
cmd.Parameters.Add("#Unit", SqlDbType.VarChar, 50).Value = _Unit
cmd.Parameters.Add("#MemberNo", SqlDbType.VarChar, 50).Value = _MemberNo
cmd.Parameters.Add("#CoName", SqlDbType.VarChar, 50).Value = coName
conn.Open
cmd.ExecuteScalar()
End Using
End If
End If
Next
End Sub

Answer 2

I still don't know why the original code didn't work, but chaning it to the following does:
Protected Function GetLabelTextForTag(tagVal As String) As String
Dim CoName As String = ""
Dim lblTag As String
For Each cntrl As Control In Me.Controls
If TypeOf cntrl Is Label Then
lblTag = CStr(DirectCast(cntrl, Label).Tag)
If lblTag = tagVal Then
CoName = DirectCast(cntrl, Label).Text
Exit For
End If
End If
Next
Return CoName
End Function