Nested If statement not selecting appropriate cell value - vba

Question

I have 3 combo boxes on a form. The first is populated when the form loads, the second is populated when the user picks a value from the first combo box, and the third is populated when the user picks a value from the second.
When the third combo box is changed, I am using a nested If statement to determine what row this combination lies in (so I can populate textboxes on the form). However, the first If Statement is failing to trigger (i.e. return a 'true' value). There is an acceptable value in the cell, so it should progress to the next If statement, but it just jumps to the end of my While statement.
Private Sub cmb_State_Change()
Dim Project, licence, state As String
Dim selectedrow As Integer
Dim LastRow As Integer
Dim i, j As Integer
selededrow = 0
Project = cmb_Project.Value
licence = cmb_Licence.Value
state = cmb_State.Value
i = 1
j = 3
While selectedrow = 0
If Worksheets("Entitlements").Cells(i, j) = Project Then
i = i + 6
If Worksheets("Entitlements").Cells(i, j) = licence Then
i = i - 1
If Worksheets("Entitlements").Cells(i, j) = state Then
selectedrow = j
End If
End If
Else
j = j + 1
i = i - 5
End If
Wend
End Sub
Can anybody see why it would be behaving like this?

Answer 1

Cells takes its arguments as rows then columns so you need to reverse i and j in your code. When you do Range("C4") it is columns then rows i.e. column C, row 4 - but Cells is the other way around.
So, currently you have
If Worksheets("Entitlements").Cells(i, j) = Project Then
i = i + 6
If Worksheets("Entitlements").Cells(i, j) = licence Then
i = i - 1
If Worksheets("Entitlements").Cells(i, j) = state Then
selectedrow = j
Which is making your second lookup 6 rows down - not 6 columns across.
Rewrite those as:
If Worksheets("Entitlements").Cells(j, i) = Project Then
i = i + 6
If Worksheets("Entitlements").Cells(j, i) = licence Then
i = i - 1
If Worksheets("Entitlements").Cells(j, i) = state Then
selectedrow = j
Another option
You can just rewrite the code block as this:
r = 3
While selectedrow = 0
If Worksheets("Entitlements").Cells(r, 1) = Project And _
Worksheets("Entitlements").Cells(r, 7) = licence And _
Worksheets("Entitlements").Cells(r, 6) = State Then
selectedrow = r
Else
r = r + 1
End If
Wend
An even better option
Using the While..Wend loop means the code will run to the last row (over million rows) in the sheet if there is no match. You can use a standard bit of code to find the last row in your data:
Set ws = Worksheets("Entitlements")
LastRow = ws.Cells(ws.Rows.Count, "A").End(xlUp).Row
Then use a For..Next loop over that range. For example:
Option Explicit
Private Sub cmb_State_Change()
Dim Project As String, licence As String, state As String
Dim selectedrow As Integer
Dim LastRow As Integer
Dim r As Integer
Dim ws As Worksheet
selectedrow = 0
Project = "hello" 'cmb_Project.Value
licence = "world" 'cmb_Licence.Value
state = "stuff" 'cmb_State.Value
Set ws = Worksheets("Entitlements")
LastRow = ws.Cells(ws.Rows.Count, "A").End(xlUp).Row
For r = 3 To LastRow
If ws.Cells(r, 1) = Project And _
ws.Cells(r, 7) = licence And _
ws.Cells(r, 6) = state Then
selectedrow = r
Exit For
Next r
End Sub
Note the use of Option Explicit to catch any typos in your code. In your original question you had Dim selectedrow As Integer and selededrow = 0 which would have thrown a compile time error if you were using `Option Explicit'.