Fill Each Cell With Formula - vba

Question

I am attempting to write a macro that will
1) store the value of each cell in column A in a variable searchstring
the pieces of code that I Think does this is
lr = Cells(Rows.Count, 2).End(xlUp).Row
For i = 2 To lr
searchstring = ws.Cells(i, 1).Value
2) Take the variable searchstring and determine if it exists in column A of the sheet called rsca.
4) If it does update column N with Yes
5) If it does not update column N with No
This is my full syntax, but everytime I step through my code it hits the For line and immediately jumps to the End Function My worksheet has data in it, column A has roughly 40 rows to be precise (but this could fluctuate up or down, so I do not want to hardcode an end cell)
How should this syntax be altered so that it will achieve my desired result above?
Public Function CheckIfCurrent()
Dim ws As Worksheet, searchstring As String, i As Long
Set ws = Sheets("ers")
lr = Cells(Rows.Count, 2).End(xlUp).Row
For i = 2 To lr
searchstring = ws.Cells(i, 1).Value
With .Range("N2:N" & .Cells(.Rows.Count, "A").End(xlUp).Row)
.Formula = IIf(IsError(Application.Match(searchstring, Sheets("rsca").Columns(1), 0)), "No", "Yes")
.Value = .Value
End With
Next i
End Function

Answer 1

This is my understanding of the requirements:
Apply a formula, to column N of worksheet ers, that validates if the value in the same row of column A is present in column A of worksheet rsca.
The formula shall return Yes if the value is found and No otherwise.
As the objective is to return the desired result using an excel formula there is no need to loop trough any of the ranges involved.
This solution applies to the Target Range the following formula:
=IF( ISERROR( MATCH( RC1, #rSrc, 0 ) ), ""No"", ""Yes"" )
Where:
The Target Range is located in sheet ers at N2:Nr (r is the last row with data in column A)
#rSrc represents address of the Source Range located in sheet rsca at A2:Ar (r is the last row with data in column A)
The following code:
Uses a constant to hold the excel formula.
Gets the last row with data from each worksheet.
Builds the Target and Source range.
Updates the excel formula with the source range address.
And applies the excel formula to the Target Range, leaving the resulting values.
Try this code:
Public Sub CheckIfCurrent_Published()
Const kFml As String = "=IF( ISERROR( MATCH( RC1, #rSrc, 0 ) ), ""No"", ""Yes"" )"
Dim rTrg As Range, rSrc As Range
Dim sFml As String
Rem Set Target Range (Sheet `ers`)
With ThisWorkbook.Worksheets("ers")
Set rTrg = .Range("N2:N" & .Cells(.Rows.Count, 1).End(xlUp).Row)
End With
Rem Set Target Range (Sheet `rsca`)
With ThisWorkbook.Worksheets("rsca")
Set rSrc = .Range("A1:A" & .Cells(.Rows.Count, 1).End(xlUp).Row)
End With
Rem Reset Formula
sFml = kFml
sFml = Replace(sFml, "#rSrc", rSrc.Address(ReferenceStyle:=xlR1C1, External:=1))
Rem Apply Formula
With rTrg
.FormulaR1C1 = sFml
.Value = .Value2
End With
End Sub

Answer 2

How about this?
Public Sub CheckIfCurrent()
Dim searchstring As String
Dim i As Long
With ThisWorkbook.Worksheets("ers")
lr = .Cells(.Rows.Count, 1).End(xlUp).Row
For i = 2 To lr
searchstring = .Cells(i, 1).Value
With .Range("N2:N" & lr)
.Formula = IIf(IsError(Application.Match(searchstring, Sheets("rsca").Columns(1), 0)), "No", "Yes")
.Value = .Value
End With
Next i
End With
End Sub