How to use wildcard in excel vba internet explorer - vba

Question

could you please tell me how to use wildcards in excel vba internet explorer?
id="btn_edit_card_1NLQNQD0D93O"
everytime that number in different. How to click that button via
document.getElementById
There is no class in code
<a id="btn_edit_card_1NLQNQD0D93O" href="/trades/bejelentes_egyszerusitett/1NLQNQD0D93O">Editing basic data</a>

Answer 1

As #Nathan_Sav suggested, very wisely I might add, that you will have to work around your problem with collections. For example, loop through all the "a" tags until you find one that "btn_edit_card_" as part of it's name. This will work unless there are more than one "a" tags with that phrase in it.
Set els = ie.Document.getElementsByTagName("a")
For Each el In els
If el.ID Like "btn_edit_card*"
el.click
Exit For
' Debug.Print el.ID, el.Name
End If
Next el

Answer 2

If your IE version is 9 or above you can use the querySelectorAll method of the HTMLDocument class.
This uses CSS selectors to enable filtering of elements by their attributes. In your case you are looking for a elements with an id beginning with btn_edit_card. The selector for this would be:
a[^=btn_edit_card]
Where the ^= means begins with.
See the example code below that pulls comments from this very page - they are all tr elements in a table beneath your question which all have id of comment-123456 where the number can change from comment to comment (because they are stored uniquely in the database etc):
Option Explicit
Sub GetElementByWildcard()
Dim objIe As InternetExplorer
Dim objDoc As HTMLDocument
Dim objElements As IHTMLDOMChildrenCollection
Dim objElement As Object
Dim lngCounter As Long
On Error GoTo ExitFunction
'get page content
Set objIe = New InternetExplorer
objIe.Visible = False
objIe.navigate "http://stackoverflow.com/questions/42225761/how-to-use-wildcard-in-excel-vba-internet-explorer"
Do While objIe.Busy
Application.Wait DateAdd("s", 1, Now)
Loop
'get document
Set objDoc = objIe.document
'get any <tr> with an id starting with comment-
Set objElements = objDoc.querySelectorAll("tr[id^=comment-]")
'iterate output
lngCounter = 0
While lngCounter < objElements.Length
Set objElement = objElements.Item(lngCounter)
Debug.Print objElement.innerText
lngCounter = lngCounter + 1
Wend
ExitFunction:
If Err.Number <> 0 Then
Debug.Print Err.Description
End If
objIe.Quit
Set objDoc = Nothing
Set objIe = Nothing
End Sub