SUMIFS Formula in VBA with "<" - vba

Question

Please could you tell me what is wrong with my second last SUMIFS formula where I use " < " &$F$1. All that is returned is FALSE in all the cells. The last SUMIFS without the < works fine.
Sub SumGroups()
Worksheets("Database").Activate
Dim lastCode, lastFiltCode As Integer
Dim Formula As String
'Determine Last Row in Column O (Unfiltered Codes)
lastCode = Range("O" & Rows.Count).End(xlUp).Row
'Filter Unique Codes into Column A Sheet2
Range("O1:O" & lastCode).AdvancedFilter Action:=xlFilterCopy, _
CopyToRange:=Sheet2.Range("A1"), Unique:=True
'Determine last Row in Column A (Filtered Codes)
Worksheets("Sheet2").Activate
lastFiltCode = Sheet2.Range("A" & Rows.Count).End(xlUp).Row
'Place SUMIF Formulas in Columns Sheet2
Worksheets("Sheet2").Range("B2:B" & lastFiltCode).Formula = _
"=SUMIFS(Database!$M$2:$M$" & lastCode & ",Database!$O$2:$O$" & lastCode & ",A2)"
Worksheets("Sheet2").Range("D2:D" & lastFiltCode).Formula = _
"=SUMIFS(Database!$M$2:$M$" & lastCode & ",Database!$O$2:$O$" & lastCode & ",A2,Database!$I$2:$I$" & lastCode & "," < " &$F$1)"
Worksheets("Sheet2").Range("F2:F" & lastFiltCode).Formula = _
"=SUMIFS(Database!$M$2:$M$" & lastCode & ",Database!$O$2:$O$" & lastCode & ",A2,Database!$I$2:$I$" & lastCode & ",$F$1)"
End Sub

Answer 1

Just to clarify why the other answers work:
SumIfs (as well as various other Excel functions requiring string operators (such as CountIf) expect that logical operators and their following statements be expressed as a string. I.e. should be enclosed in speech marks e.g. "myString".
Since a formula is also a string e.g. ActiveCell.Formula = "=If(A1=3, 1, 0)" the compiler gets confused about which set of quotation marks denotes the string. So for example this will not work: ActiveCell.Formula = "=If(A1=3, "Yes", "No")".
Technically the way to deal with this is to enclose the required quotation mark in quotation marks of it own; """ myValue """.
However, this quickly becomes confusing. Instead, use the Character function to return the char you require. In this case 34; chr(34) & myvalue & (chr34).

Answer 2

Worksheets("Sheet2").Range("D2:D" & lastFiltCode).Formula = _
"=SUMIFS(Database!$M$2:$M$" & lastCode & ",Database!$O$2:$O$" & lastCode & ",A2,Database!$I$2:$I$" & lastCode & ","" < "" &$F$1)"
This will do it.
put < in quotes.

Answer 3

First, in order to get <$F$1 inside the formula I use the Chr(34) to add the parenthesis "" inside the formula.
Besides that, you are mixing-up a few things:
Try to avoid using Worksheets("Database").Activate and Worksheets("Sheet2").Activate, and instead use fully qualified worksheets and ranges, like: With Worksheets("Database") and inside lastCode = .Range("O" & .Rows.Count).End(xlUp).Row.
You have Sheet2 and Worksheets("Sheet2"), these two not always mean the same worksheet. You could rename Sheet2 (by code name) to "Something", and that will be your 2nd sheet, and rename Sheet3 (by code name) to "Sheet2" and you have a problem. So decide on which method you want to use (I prefer to use Worksheets("Sheet2")).
Dim lastCode, lastFiltCode As Integer means lastCode is actually Variant and lastFiltCode is Integer. Anyway, it's better to use Long for both of these variables when you are trying to get the last row.
Code
Option Explicit
Sub SumGroups()
Dim lastCode As Long, lastFiltCode As Long
'Determine Last Row in Column O (Unfiltered Codes)
With Worksheets("Database")
lastCode = .Range("O" & .Rows.Count).End(xlUp).Row
'Filter Unique Codes into Column A Sheet2
.Range("O1:O" & lastCode).AdvancedFilter Action:=xlFilterCopy, _
CopyToRange:=Worksheets("Sheet2").Range("A1"), Unique:=True
End With
With Worksheets("Sheet2")
'Determine last Row in Column A (Filtered Codes)
lastFiltCode = .Range("A" & .Rows.Count).End(xlUp).Row
'Place SUMIF Formulas in Columns Sheet2
.Range("B2:B" & lastFiltCode).Formula = _
"=SUMIFS(Database!$M$2:$M$" & lastCode & ",Database!$O$2:$O$" & lastCode & ",A2)"
.Range("D2:D" & lastFiltCode).Formula = _
"=SUMIFS(Database!$M$2:$M$" & lastCode & ",Database!$O$2:$O$" & lastCode & ",A2,Database!$I$2:$I$" & lastCode & "," & Chr(34) & "<" & Chr(34) & "&$F$1)"
.Range("F2:F" & lastFiltCode).Formula = _
"=SUMIFS(Database!$M$2:$M$" & lastCode & ",Database!$O$2:$O$" & lastCode & ",A2,Database!$I$2:$I$" & lastCode & ",$F$1)"
End With
End Sub