Gawk: Insert line using lookup data from another file - awk

Question

I'm trying to insert lines into a file, where the data being inserted is based on data stored in another file. I've tried this in both Sed and Awk, but can't figure out in either how to access the second file. This is probably a stretch for Sed, perhaps less so for Awk?
The main file:
# alpha --
some data
some more data
# beta --
some data
some more data
# gamma --
some data
some more data
The lookup file:
alpha This is a description of alpha
gamma This guys description
delta And a third description
The result should look like this:
# alpha --
Description = This is a description of alpha
some data
some more data
# beta --
some data
some more data
# gamma --
Description = This guys description
some data
some more data
Notice that the lookup file may not have a description for the item, and that's ok; the "Description = " line will just be omitted.
I figured this much out in Awk, but don't know how to reference the lookup file:
awk '{
if ($0 ~ /^# [^ ]* --/) {
print $0;
print "Description = "; # How to lookup $2's description??
} else {
print $0;
}
}' <file1.txt
How can I obtain the description from the second file using Awk? Or is there a better tool for this? Thanks!

Answer 1

another similar awk
$ awk 'NR==FNR {k=$1; sub(/^\S+\s+/,"Description = "); dict[k]=$0; next}
1;
/^#/ {if($2 in dict) print dict[$2]}' dict file

Answer 2

You could do something like this, supplying both files on the awk command line in the logical order (descriptions first, so it can read and store them, followed by the data that needs them inserted):
$ awk '(NR == FNR) {
desc[$1]=$2;
for (i=3;i<=NF;i++) {
desc[$1]=desc[$1]" "$i
};
}
(NR > FNR) {
print;
if (/^#/) {
print "Description = "desc[$2];
}
}' desc.txt main.txt
Which produces this output given your sample file contents:
# alpha --
Description = This is a description of alpha
some data
some more data
# beta --
Description =
some data
some more data
# gamma --
Description = This guys description
some data
some more data
Explanation:
The awk variable NR contains the Number of Records seen so far. Normally, a record is a line - although you can change the record separator - so this is effectively the current line number, counted continuously across all the files being processed. In this case its value will run from 1 to 14.
The variable FNR (File Number of Records) works the same way, but resets to 1 at the start of each new file. So in this case its value will run from 1 to 4 and then 1 to 10.
By comparing these two values, the program can determine which file is currently being processed. If NR and FNR are the same, we know we're in the first file, and use the contents of the line to populate the associative array desc. The first field ($1) is the key; we concatenate the rest of the fields together to form the value.
If NR is not equal to FNR (it can only be greater, never less), we know we're in the second file. In that case, we first print the line (which we always do, so we just make it unconditional instead of repeating the statement). Then we check to see if we need to append the description. If we do, look it up in the desc array - using $2 (the second whitespace-separated field on the line, the first being the "#") as the lookup key.