stop save changes if multiple conditions not met excel vba - vba

Question

I'm new in vba, i've been spending time and time surfing on internet trying to find solution but i could'nt
can someone assist on the below code, i want excel to force users to inter data in column K L and S whenever column B filled in with data (i.e column B is not empty) before save it.
may i know what i've missed below to make it run?!
Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean)
Set rng = Worksheets("Sheet1").Range("B7:B10000")
Application.ScreenUpdating = False
For Each cell In rng
If Not IsEmpty(cell) And IsEmpty(cell.Offset(-1, 9)) Then
Application.Goto cell.Offset(-1, 9)
Cancel = True
MsgBox "Save is cancelled!" & _
vbNewLine & "" & vbNewLine & "Please fill in cells in column K."
End If
Next
Application.ScreenUpdating = True
End Sub
Private Sub column_L()
Set rng = Worksheets("Sheet1").Range("B7:B10000")
Application.ScreenUpdating = False
For Each cell In rng
If Not IsEmpty(cell) And IsEmpty(cell.Offset(-1, 10)) Then
Application.Goto cell.Offset(-1, 10)
Cancel = True
MsgBox "Save is cancelled!" & vbNewLine & "" & vbNewLine & "Please fill in cells in column L."
End If
Next
Application.run macro:="column_L"
End Sub
Private Sub column_S()
Set rng = Worksheets("Sheet1").Range("B7:B10000")
Application.ScreenUpdating = False
For Each cell In rng
If Not IsEmpty(cell) And IsEmpty(cell.Offset(-1, 17)) Then
Application.Goto cell.Offset(-1, 17)
Cancel = True
MsgBox "Save is cancelled!" & _
vbNewLine & "" & vbNewLine & "Please fill in cells in column S."
End If
Next
Application.run macro:="column_S"
End Sub

Answer 1

You had two subroutines (column_L and column_S) that weren't being called from anywhere but, if they had been, they would have gone into an infinite loop because they called themselves.
Your code should just be placed in the BeforeSave event as follows:
Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean)
Dim rng As Range
Set rng = Worksheets("Sheet1").Range("B7:B10000")
Cancel = True
For Each cell In rng
If Not IsEmpty(cell) Then
'Check column K of current row
If IsEmpty(cell.Offset(0, 9)) Then
Application.Goto cell.Offset(0, 9)
MsgBox "Save is cancelled!" & _
vbNewLine & vbNewLine & "Please fill in cells in column K."
Exit Sub
End If
'Check column L of current row
If IsEmpty(cell.Offset(0, 10)) Then
Application.Goto cell.Offset(0, 10)
MsgBox "Save is cancelled!" & _
vbNewLine & vbNewLine & "Please fill in cells in column L."
Exit Sub
End If
'Check column S of current row
If IsEmpty(cell.Offset(0, 17)) Then
Application.Goto cell.Offset(0, 17)
MsgBox "Save is cancelled!" & _
vbNewLine & vbNewLine & "Please fill in cells in column S."
Exit Sub
End If
End If
Next
Cancel = False
End Sub
(I removed your ScreenUpdating code, as your code doesn't actually update any cells, so I don't think you should see any flickering of the screen other than the movement caused by the GoTo, and you probably want the users to see that.)