Hive concat two map object - hive

Question

I have two tables as follow in hive:
Table 1
key1 | value1
int | map(int,array(int))
Table 2
key2 | value2
int | map(int,array(int))
and now I join the table on key and I want to concat two maps that have the same key. In other words the final should looklike .
Table
key | value
int | map(int,array(int))
I tried to use function collect_set when I am joining as follows:
collect_set(value1,value2)
but it through exception that only one input is required. Any thoughts or comments?
Thanks

Answer 1

COLLECT_SET() is an aggregate function so it wouldn't really be useful (or valid) if you are trying to combine things. One thing you could try is using COMBINE(). It can be found in this library of UDFs here. Suppose you had some data like:
table0:
idx map_kv
0 {2:[1,2,3,4], 3:[5,6,7,8,9]}
table1:
idx map_kv
0 {2:[5,6,7,8,9], 3:[1,2,3,4]}
Then you could do
Query:
ADD JAR /path/to/jar/brickhouse-0.7.1.jar;
CREATE TEMPORARY FUNCTION COLLECT AS 'brickhouse.udf.collect.CollectUDAF';
CREATE TEMPORARY FUNCTION COMBINE AS 'brickhouse.udf.collect.CombineUDF';
SELECT idx
, COLLECT(map_key, arr) AS final_map
FROM (
SELECT a.idx
, a.map_key
, COMBINE(map_val_0, map_val_1) AS arr
FROM (
SELECT idx
, map_key
, map_val_0
FROM database.table0
LATERAL VIEW EXPLODE(map_kv) exptbl0 AS map_key, map_val_0 ) a
JOIN (
SELECT idx
, map_key
, map_val_1
FROM database.table1
LATERAL VIEW EXPLODE(map_kv) exptbl1 AS map_key, map_val_1 ) b
ON a.idx=b.idx AND a.map_key=b.map_key ) c
GROUP BY idx;
This will produce:
Output:
idx final_map
0 {2:[1,2,3,4,5,6,7,8,9], 3:[5,6,7,8,9,1,2,3,4]}