VLOOKUP INSIDE A LOOP (FOR) VISUAL BASIC EXCEL - vba

Question

I have the following problem
I have a VLOOKUP that I want to run in a loop, but when vlookup doesnt find a corresponding value then it halts the script. If I handle the error with error handler, it will jump and also halt it anyway.
Sub Botón1_Haga_clic_en()
Dim filas As Integer
Dim desdefila As Integer
filas = InputBox("Cuantas files tiene éste bloque de pagos?")
desdefila = InputBox("Desde que fila empieza?")
filasfinal = filas + desdefila
For x = desdefila To filasfinal
Dim Nombre As String
Dim Rango As Range
Set Rango = Sheets(6).Range("A:B")
Nombre = Application.WorksheetFunction.VLookup(Range("A" & desdefila).Value, Rango, 2, 0)
Range("E" & desdefila).Value = Nombre
desdefila = desdefila + 1
Next
End Sub
Any ideas on how to go back to the loop or handling this error ?

Answer 1

You can handle a Vlookup error using the following structure:
Dim myValue As Variant
myValue = Application.VLookup("Some Value", Range("A:B"), 2, False)
If IsError(myValue) Then
'Code for when not found
Else
'Code for when found
End If
Note that this does not use Application.WorksheetFunction.VLookup, but instead uses Application.VLookup.
So, for your code, the error handling would be inserted to look something like:
Dim Nombre As Variant
Dim Rango As Range
Set Rango = Sheets(6).Range("A:B")
Nombre = Application.VLookup(Range("A" & desdefila).Value, Rango, 2, 0)
If IsError(Nombre) Then
'Code for when not found
Else
Range("E" & desdefila).Value = Nombre
End If
desdefila = desdefila + 1

Answer 2

The early-bound VLookup function from WorksheetFunction will raise a runtime error if the lookup fails.
If a failing lookup is an exceptional thing and you want to handle it cleanly, you need an error-handling subroutine:
On Error GoTo ErrHandler
For ...
Nombre = Application.WorksheetFunction.VLookup(Range("A" & desdefila).Value, Rango, 2, 0)
'...
Next
Exit Sub
ErrHandler:
' execution jumps here in case of a failed lookup
MsgBox "Lookup of '" & Range("A" & desdefila) & "' failed. Please verify data."
'if you want to resume the loop, you can do this:
Resume Next
'otherwise execution of the procedure ends here.
End Sub
If you know a failing lookup is a possibility but not quite exceptional, and you just want to deal with it and move on, you can use On Error Resume Next / On Error GoTo 0 to hide the error instead:
On Error Resume Next
Nombre = Application.WorksheetFunction.VLookup(Range("A" & desdefila).Value, Rango, 2, 0)
If Err.Number <> 0 Then Nombre = "Not Available"
Err.Clear
On Error GoTo 0
Alternatively, you can use the late-bound version (as in elmer007's answer) which extends the Application interface; instead of raising a VBA runtime error when lookup fails, it returns an error value that you can check with the IsError function:
Dim Nombre As Variant 'note "As Variant"
For ...
Nombre = Application.VLookup(Range("A" & desdefila).Value, Rango, 2, 0)
If IsError(Nombre) Then
'handle error value
End If
'...
Next
One of the advantages of using the early-bound version, is that you get IntelliSense for the parameters, whereas you need to know exactly what you're doing when you use the late-bound version.