VBA - Searching the first repeated word within a Range - vba

Question

I've implemented this macro whereby if i run it, it will show me the column and row of the word "needle" in the range A1:Z20. Although if there are multiple words of "needle" it will only output the last. How can I change this code to show me the first occurrence of the word?
Hope this makes sense, and here is my code so far:
Sub NeedleSearch()
Dim SearchSpace As Variant
Dim found As Boolean
found = False
SearchSpace = Range("A1:z20").Value
Dim i As Integer, j As Integer
For i = 1 To 20
For j = 1 To 26
If SearchSpace(i, j) = "needle" Then
Range("A25").Value = "Column " & j
Range("B25").Value = "Row " & i
found = True
End If
Next j
Next i
If found = False Then
Range("A25").Value = "needle not found"
Range("B25").Value = " "
End If
End Sub
With No Repeated Words
With 1 Repeated Word

Answer 1

If you need only first occurense just quit your loops!
Sub NeedleSearch()
Dim SearchSpace As Variant
Dim found As Boolean
found = False
SearchSpace = Range("A1:z20").Value
Dim i As Integer, j As Integer
For i = 1 To 20
For j = 1 To 26
If SearchSpace(i, j) = "needle" Then
Range("A25").Value = "Column " & j
Range("B25").Value = "Row " & i
found = True
End If
If found Then _
Exit For
Next j
If found Then _
Exit For
Next i
If found = False Then
Range("A25").Value = "needle not found"
Range("B25").Value = " "
End If
End Sub

Answer 2

To elaborate further: What this code actually does, if there are multiple instances of needle is, it will print all instances of found cells into A25:B25. Let's say there are 3 instances of needle e.g. in A1, B2 and C3. Your loop prints A1 into A25:B25 first, then B2 and then C3. Because it is happening so fast, you only see C3 or what you called the "last occurence".
What you can do to print out all solutions (which is what I'm guessing you're trying to do in the end) you could change your code to something like this:
Sub NeedleSearch()
Dim SearchSpace As Variant
Dim found As Boolean
found = False
SearchSpace = Range("A1:z20").Value
Dim ws As Worksheet
Dim i As Integer
Dim j As Integer
Dim k As Integer
Set ws = ThisWorkbook.Sheets(1)
k = 25
For i = 1 To 20
For j = 1 To 26
If SearchSpace(i, j) = "needle" Then
ws.Cells(k, 1).Value = "Occurence " & k - 24
ws.Cells(k, 2).Value = "Column " & j
ws.Cells(k, 3).Value = "Row " & i
k = k + 1
found = True
End If
Next j
Next i
If found = False Then
ws.Range("A25").Value = "needle not found"
End If
End Sub
Change your Sheet ID accordingly.
HTH

Answer 3

you can avoid loops by means of Find() method of Range object:
Option Explicit
Sub NeedleSearch()
Dim f As Range
Set f = Range("A1:Z20").Find(what:="needle", LookIn:=xlValues, lookat:=xlWhole, After:=Range("Z20"), SearchOrder:=xlByRows)
If f Is Nothing Then
Range("A25").Value = "needle not found"
Range("B25").Value = " "
Else
Range("A25").Value = "Column " & f.Column
Range("B25").Value = "Row " & f.Row
End If
End Sub
that can also be rewritten as follows:
Sub NeedleSearch()
Dim f As Range
Dim arr As Variant
Set f = Range("A1:Z20").Find(what:="needle", LookIn:=xlValues, lookat:=xlWhole, After:=Range("Z20"), SearchOrder:=xlByRows)
If f Is Nothing Then
arr = Array("needle not found", " ")
Else
arr = Array("Column " & f.Column, "Row " & f.Row)
End If
Range("A25:B25").Value = arr
End Sub