Access VBA: Adding 'filename' field when importing multiple files - sql

Question

I have some working code that loops through a folder full of Excel files, and imports a table from each into the an Access table. All I'm trying to do is add a field at the end of the table called FileName that has the name of the source Excel file.
I've done some Googling and found this solution:
How to add file name when importing multiple Excel files to one Access table
I've tried to incorporate the solution into my code, but when I reach the execute statement, I get:
Run-time error '3061' Too few parameters. Expected 2.
I think the problem is just with the strSQL statement and/or the way I'm executing it at the end.
Public Sub Command0_Click()
Dim strFile As String 'Filename
Dim strFileList() As String 'File Array
Dim intFile As Integer 'File Number
Dim filename As String
Dim path As String
Dim qdf As DAO.QueryDef
Set db = CurrentDb()
'make the UPDATE a parameter query ...
strSQL = "UPDATE Test SET FileName=[pFileName] WHERE FileName Is Null OR
FileName='';"
Set qdf = db.CreateQueryDef(vbNullString, strSQL)
path = "C:\Users\u005984\Desktop\Test\"
'Loop through the folder & build file list
strFile = Dir(path & "*.xlsx")
While strFile <> ""
'add files to the list
intFile = intFile + 1
ReDim Preserve strFileList(1 To intFile)
strFileList(intFile) = strFile
strFile = Dir()
Wend
'see if any files were found
If intFile = 0 Then
MsgBox "No files found"
Exit Sub
End If
'cycle through the list of files
For intFile = 1 To UBound(strFileList)
filename = path & strFileList(intFile)
DoCmd.TransferSpreadsheet acImport, 9, "Test", filename, True
'Add filename field
qdf.Parameters("pFileName").Value = strFileList(intFile)
qdf.Execute dbFailOnError
Next intFile
End Sub
I'm new to Access VBA and SQL, and can't figure out why its expecting 2 parameters. Grateful for any help.

Answer 1

Adjust your SQL query, your's doesn't contain the parameter.
strSQL = "PARAMETERS pfilename Text ( 255 ); UPDATE Test SET FileName=[pFileName] WHERE FileName Is Null OR FileName='';"

Answer 2

Adding a FileName field is markedly different than updating its value. Hence, you need two SQL action queries: ALTER and UPDATE statements.
Specifically, the query requires two components that are unknown by the engine: FileName column and [pFileName] parameter value. Most likely, your Excel worksheets do not have a FileName column being imported into Test table.
Consider the following setup employing an ALTER statement within loop (only on very first iteration since all worksheets append to same table):
'Add filename field
For intFile = 1 To UBound(strFileList)
filename = path & strFileList(intFile)
DoCmd.TransferSpreadsheet acImport, 9, "Test", filename, True
If intFile = 1 then
' ALTER TABLE
CurrentDb.Execute "ALTER TABLE [Test] ADD COLUMN [FileName] TEXT(255)", dbFailOnError
End If
' UPDATE TABLE (PASSING PARAM VALUE)
qdf.Parameters("pFileName").Value = strFileList(intFile)
qdf.Execute dbFailOnError
Next intFile