Overwrite paste whole row if copied row's first column value matches - vba

Question

I have list of ship data in sheet2. First column is ship's name and the others columns are that ship's details. A row below is another ship and so on. What I'm trying to do is copy a row of ship data in sheet1 and paste it to sheet2, but if sheet2 already has that ship i want that ship in sheet2's row replaced with copied one from sheet1.
What I got so far is I copy the row from sheet1 and paste it to sheet2's first avaible empty row and then sort it in alphabetical order :P. So I have lots of rows with the same ship.
Here is my code:
Private Sub CommandButton2_Click()
Application.ScreenUpdating = False
Dim copySheet As Worksheet
Dim pasteSheet As Worksheet
Set copySheet = Worksheets("sheet1")
Set pasteSheet = Worksheets("sheet2")
copySheet.Range("A5:AT5").Copy
pasteSheet.Cells(Rows.Count, 1).End(xlUp).Offset(1, 0).PasteSpecial xlPasteValues
Application.CutCopyMode = False
Worksheets("sheet2").Activate
Sheets("sheet2").Range("A2").CurrentRegion.Select
Selection.Sort Key1:=Sheets("sheet2").Range("A1"), Order1:=xlAscending, Header:=xlYes, _
OrderCustom:=1, MatchCase:=False, Orientation:=xlTopToBottom, _
DataOption1:=xlSortNormal
Set Rng = Nothing
Application.CutCopyMode = False
Application.ScreenUpdating = True
End Sub

Answer 1

Here:
Private Sub CommandButton2_Click()
Application.ScreenUpdating = False
Dim Rng As Range
Sheets("Sheet1").Range("A5:AT5").Copy ' copies the row mentioned
Sheets("Sheet2").Activate
Set Rng = Range("A:A").Find(What:=Sheets("Sheet1").Range("A5").Value, LookIn:=xlValues, LookAt:=xlWhole, MatchCase:=True) ' Check to see if ship is already in sheet2 ("Rng = nothing" means it's not, "Rng = [Ship's name]" means it is)
If Not Rng Is Nothing Then 'if it's not nothing, it's somthing (ship's name)
Rng.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks:=False, Transpose:=False 'Pastes over old record of ship
Else
Range("A" & Range("A" & Cells.Rows.Count).End(xlUp).Row + 1).PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks:=False, Transpose:=False ' enters ne entry for ship
End If
Application.CutCopyMode = False
Sheets("sheet2").Range("A2").Sort Key1:=Sheets("sheet2").Range("A1"), Order1:=xlAscending, Header:=xlYes, OrderCustom:=1, MatchCase:=False, Orientation:=xlTopToBottom, DataOption1:=xlSortNormal
Set Rng = Nothing
Application.CutCopyMode = False
Application.ScreenUpdating = True
End Sub

Answer 2

I have modified your code and added a part to find the ship in sheet1 (A5) in sheet2. If found, code will replace the data else add to the end of the data.
Sub CopyShip()
Dim copySheet As Worksheet
Dim pasteSheet As Worksheet
Set copySheet = Worksheets("sheet1")
Set pasteSheet = Worksheets("sheet2")
Dim rowToCopy As Integer
rowToCopy = 5 ' this variable in case a for loop is implemented in future
Dim findShip As Range
'find current ship in sheet2
Set findShip = pasteSheet.Cells.Find(What:=copySheet.Range("A" & rowToCopy), LookIn:=xlFormulas, _
LookAt:=xlWhole, SearchOrder:=xlByRows, SearchDirection:=xlNext, _
MatchCase:=False, SearchFormat:=False)
copySheet.Range("A" & rowToCopy & ":AT" & rowToCopy).Copy
If findShip Is Nothing Then
'current ship was not found
pasteSheet.Cells(Rows.Count, 1).End(xlUp).Offset(1, 0).PasteSpecial xlPasteValues
Else
'ship with same name was found
'assuming all data is within columns A to AT
'other wise need to clear the entire row before pasting
pasteSheet.Cells(findShip.Row, 1).PasteSpecial xlPasteValues
End If
Application.CutCopyMode = False
Worksheets("sheet2").Activate
Sheets("sheet2").Range("A2").CurrentRegion.Select
Selection.Sort Key1:=Sheets("sheet2").Range("A1"), Order1:=xlAscending, Header:=xlYes, _
OrderCustom:=1, MatchCase:=False, Orientation:=xlTopToBottom, _
DataOption1:=xlSortNormal
End Sub