How to save a given range in excel as csv? - vba

Question

I have data in excel columns and I want to extract first 7 columns and save it in another csv file. The file name would be in a particular format basis the information I collect from user using a form and other details such as time-stamp.
I am using the following code:
With Application.FileDialog(msoFileDialogFolderPicker)
.Title = "Select a Folder"
.AllowMultiSelect = False
.InitialFileName = "" '<~~ The start folder path for the file picker.
If .Show <> -1 Then GoTo NextCode
MyPath = .SelectedItems(1) & "\"
End With
NextCode:
With ActiveWorkbook
.SaveAs Filename:=MyPath & MyFileName, FileFormat:=xlCSV, CreateBackup:=False
Application.DisplayAlerts = False
ThisWorkbook.CheckCompatibility = False
.Close False
End With
But this writes all the columns in the output CSV and also closes the open xls (which I don't want to close).

Answer 1

That's a rather playful approach. Maybe not too practical, I also suspect this to be rather slow with large amounts of data.
However: if you make use of recordsets in other parts of your routine, this might be worth looking into.
Option Explicit
Sub ExportRange()
Dim mytxt As String
Dim fld As Object
With GetRecordset(ThisWorkbook.Sheets(2).UsedRange)
For Each fld In .Fields
mytxt = mytxt & fld.Name & ";"
Next fld
mytxt = mytxt & vbNewLine
While Not .EOF
For Each fld In .Fields
mytxt = mytxt & fld.Value & ";"
Next fld
mytxt = mytxt & vbNewLine
.movenext
Wend
Debug.Print mytxt
End With
Open ThisWorkbook.Path & "\test.csv" For Binary Access Write As #1
Put #1, , mytxt
Close #1
End Sub
It utilizes this function for reading ranges (.UsedRange in my example) into recordsets, without having to define ADODB-references and setting up a DB-Connection:
Function GetRecordset(rng As Range) As Object
'https://usefulgyaan.wordpress.com/2013/07/11/vba-trick-of-the-week-range-to-recordset-without-making-connection/
Dim xlXML As Object
Dim rst As Object
Set rst = CreateObject("ADODB.Recordset")
Set xlXML = CreateObject("MSXML2.DOMDocument")
xlXML.LoadXML rng.Value(xlRangeValueMSPersistXML)
rst.Open xlXML
Set GetRecordset = rst
End Function
Edit:
Open ThisWorkbook.Path & "\test.csv" For Binary Access Write As #1 creates the file (if it doesnt exist) and opens it.
Obviously, you can use something like
MyPath & "\test' & format(now, "yyyymmdd_hhmmss") & ".csv"
instead to use a File with timestamp in the folder you picked with the FolderPicker