Datagrid to dbf database using vb.net - vb.net

Question

Datagrid to dbf database updating type of solution couldn't find anywhere, if anybody solve this problem please reply me.
Error - Dynamic SQL generation for the UpdateCommand is not supported against a SelectCommand that does not return any key column information.
My Code is
Dim con As New OleDbConnection
Dim ds As New DataSet
Dim dt As New DataTable
Dim da As New OleDbDataAdapter
Dim con1 As New OleDbConnection
Dim ds1 As New DataSet
Dim dt1 As New DataTable
Dim da1 As New OleDbDataAdapter
Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
con.ConnectionString = "Provider=vfpoledb.1;Data Source=C:\dbf_folder;Collating Sequence=machine;"
con.Open()
ds.Tables.Add(dt)
da = New OleDbDataAdapter("Select * from area.dbf", con)
Dim cb = New OleDbCommandBuilder(da)
cb.QuotePrefix = "["
cb.QuoteSuffix = "]"
da.Fill(dt)
dt.Merge(dt1)
dbfdatagrid.DataSource = dt.DefaultView
con.Close()
End Sub
Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
con1.Close()
con1.ConnectionString = "Provider=vfpoledb.1;Data Source=C:\dbf_folder1;Collating Sequence=machine;"
con1.Open()
da1 = New OleDbDataAdapter("Select * from area.dbf", con1)
Dim cb = New OleDbCommandBuilder(da1)
cb.QuotePrefix = "["
cb.QuoteSuffix = "]"
Dim columns(5) As DataColumn
columns(4) = dt.Columns("NAME")
dt.PrimaryKey = columns
da1.Fill(dt1)
da1.Update(dt)

Answer 1

Looking at your code (I don't know VB, I am more of a C# guy), it is not a matter of VFP, your code is strange given any database.
When the database is VFP, you shouldn't use those QuotePrefix and QuoteSuffix. That by itself, creates a buggy update command. You could also write the update command manually.
Although I don't know VB, doesn't your code create a 6 elements DataColumn array and set only 5th, leaving others as NULL for the primary key? What could be the purpose? Actually you don't need to specify a primary key if you don't have a valid one (then you need to write your update command manually - also it would be your problem if you can build a valid update command to correctly update the rows you need). Let's assume, you go with good database principles and have a primary key in your table. Then you don't need to write manual update, simply have CommandBuilder build it for you. ie:
Sub Main()
Dim tbl As New DataTable()
Dim adapter = New OleDbDataAdapter("select * from Customer", "Provider=VFPOLEDB;Data Source=C:\PROGRAM FILES (X86)\MICROSOFT VISUAL FOXPRO 9\SAMPLES\data")
adapter.Fill(tbl)
Dim cb = New OleDbCommandBuilder(adapter)
adapter.UpdateCommand = cb.GetUpdateCommand()
Dim f = New Form()
Dim btn = New Button With {
.Top = 10,
.Text = "Update"
}
Dim dgv = New DataGridView With {
.Top = 50,
.DataSource = tbl
}
f.Controls.AddRange(New Control() {btn, dgv})
AddHandler btn.Click, Sub(sender, args)
adapter.Update(tbl)
End Sub
f.Show()
End Sub
If you have a table with no primary key that builder could extract from schema, then you could as well write your own manual update code. Just for sampling, assume you have a table in c:\Temp named NoPK (v1 i, v2 c(10)). Although it has no index information and it is a free table (builder cannot determine the PK), we know that v1 is our key and we want to update only v2, could do this:
Sub Main()
Dim tbl As New DataTable()
Dim adapter = New OleDbDataAdapter("select * from NoPK", "Provider=VFPOLEDB;Data Source=c:\Temp")
adapter.Fill(tbl)
adapter.UpdateCommand = New OleDbCommand("update NoPK set v2=? where v1=?", adapter.SelectCommand.Connection)
adapter.UpdateCommand.Parameters.AddWithValue("p1", "").SourceColumn = "v2"
adapter.UpdateCommand.Parameters.AddWithValue("p2", 0).SourceColumn = "v1"
Dim f = New Form()
Dim btn = New Button With {
.Top = 10,
.Text = "Update"
}
Dim dgv = New DataGridView With {
.Top = 50,
.DataSource = tbl
}
f.Controls.AddRange(New Control() {btn, dgv})
AddHandler btn.Click, Sub(sender, args)
adapter.Update(tbl)
End Sub
f.Show()
End Sub
Note that with OleDb, the parameters should be added to the collection in the same order with their corresponding placeholder (?) in command text (IOW you wouldn't add p2 first).