First line of sub before loop - vba

Question

This function breaks up one long continuous string into smaller ones and adds a prefix and suffix/
This line of code is giving me problems I need it because the first prefix is different to the others but it causes the first line to be produced twice not sure how to rewrite the line /code overcome this?
.WriteLine "s = """ & Trim$(Mid$(strInput, 1, intSize * AtomSize)) & """"
Here is the full suc:
Sub StringBuilder(intSize As Integer, Optional AtomSize As Long = 3)
Dim i As Long
Dim strInput As String
strInput = CreateObject("Scripting.FileSystemObject").OpenTextFile(CurrentProject.Path & "\input.txt").ReadAll
With CreateObject("Scripting.FileSystemObject").CreateTextFile(CurrentProject.Path & "\output.txt", True)
.WriteLine "s = """ & Trim$(Mid$(strInput, 1, intSize * AtomSize)) & """"
For i = 1 To Len(strInput) - intSize * AtomSize Step intSize * AtomSize
.WriteLine "s = s & """ & Trim$(Mid$(strInput, i, intSize * AtomSize)) & """"
Next
.WriteLine "s = s & """ & Trim$(Mid$(strInput, i, intSize * AtomSize)) & """"
End With
End Sub

Answer 1

Simple change
.WriteLine "s = """ & Trim$(Mid$(strInput, 1, intSize * AtomSize)) & """"
To
.WriteLine "s = """
Sub StringBuilder(intSize As Integer, Optional AtomSize As Long = 3)
Dim i As Long
Dim strInput As String
strInput = CreateObject("Scripting.FileSystemObject").OpenTextFile(CurrentProject.Path & "\input.txt").ReadAll
With CreateObject("Scripting.FileSystemObject").CreateTextFile(CurrentProject.Path & "\output.txt", True)
.WriteLine "s = """
For i = 1 To Len(strInput) - intSize * AtomSize Step intSize * AtomSize
.WriteLine "s = s & """ & Trim$(Mid$(strInput, i, intSize * AtomSize)) & """"
Next
.WriteLine "s = s & """ & Trim$(Mid$(strInput, i, intSize * AtomSize)) & """"
End With
End Sub

Answer 2

Here is a function which can be used to divide a string into groups:
Function GroupString(s As String, groupSize As Long, _
Optional delim As String = ",", _
Optional prefix As String = "", _
Optional postfix As String = "") As String
Dim n As Long, m As Long, i As Long
Dim chunks As Variant
n = Len(s)
m = Int(n / groupSize)
If n Mod groupSize = 0 Then
ReDim chunks(0 To m - 1)
Else
ReDim chunks(0 To m) 'includes final chunk of size < groupSize
End If
For i = 0 To m - 1
chunks(i) = Mid(s, 1 + i * groupSize, groupSize)
Next i
If n Mod groupSize > 0 Then
chunks(m) = Mid(s, 1 + m * groupSize) 'final chunk
End If
GroupString = prefix & Join(chunks, delim) & postfix
End Function
To test it:
Sub test()
Dim myString As String
myString = "abcd"
Debug.Print GroupString(myString, 2, , "[", "]")
myString = "This is a very long string, it would be nice if it were split into several lines, where each line is assigned to a variable"
Debug.Print GroupString(myString, 20, """" & vbCrLf & "s = s & """, "s = """, """")
End Sub
With output:
[ab,cd]
s = "This is a very long "
s = s & "string, it would be "
s = s & "nice if it were spli"
s = s & "t into several lines"
s = s & ", where each line is"
s = s & " assigned to a varia"
s = s & "ble"
To use it for your problem: read the input file into a string, and then in a single write operation, use a single write operation to write the result of the function applied to the string, using a call similar to the second example in my test code.