Cycling through different ranges to copy while looping - vba

Question

This is my current code.
Sub Loops()
Dim MyPath As String
Dim MyFileName As String
Dim output As Variant
Dim outputRange(1 To 3) As Range
Set outputRange(1) = Worksheets("vbaTest").Range("output1", Worksheets("vbaTest").Range("output1").End(xlDown))
Set outputRange(2) = Worksheets("vbaTest").Range("output2", Worksheets("vbaTest").Range("output2").End(xlDown))
Set outputRange(3) = Worksheets("vbaTest").Range("output3", Worksheets("vbaTest").Range("output3").End(xlDown))
For Each output In outputRange
'The path and file names:
MyPath = "C:\Users\x\Custom Office Templates"
MyFileName = "Test"
'Makes sure the path name ends with "\":
If Not Right(MyPath, 1) = "\" Then MyPath = MyPath & "\"
'Makes sure the filename ends with ".csv"
If Not Right(MyFileName, 4) = ".txt" Then MyFileName = MyFileName & ".txt"
'Copies the sheet to a new workbook:
Sheets("vbaTest").Range("**output1**").Copy
'The new workbook becomes Activeworkbook:
Workbooks.Add
ActiveSheet.Columns("A").Select
Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
:=False, Transpose:=False
With ActiveWorkbook
Application.DisplayAlerts = False
End With
'Brings back original sheet
Workbooks("vbaTest.csv").Activate
'Starts at the top of code
Next output
End Sub
I'm having trouble looping through the different ranges I've set when it comes to output1. "Sheets("vbaTest").Range("output1").Copy"
I'm trying to get vba to loop through the three other outputs that I've set. Any suggestions?

Answer 1

you could shorten down to:
Option Explicit
Sub Loops()
Dim MyPath As String
Dim MyFileName As String
Dim output As Variant
Dim outputRange(1 To 3) As Range
With Worksheets("vbaTest") '<--| reference your worksheet once and for all!
Set outputRange(1) = .Range("output1", .Range("output1").End(xlDown)) '<--| all "dotted" reference implicitly assume the object after preceeding 'With' keyword as the parent one
Set outputRange(2) = .Range("output2", .Range("output2").End(xlDown))
Set outputRange(3) = .Range("output3", .Range("output3").End(xlDown))
End With
For Each output In outputRange
Workbooks.Add.Worksheets(1).Range("A1").Resize(output.Rows.Count).Value = output.Value
Next output
' the following code doesn't currently depend on looping variable
' so I put it outside the loop-> I guess you're setting the new workbooks names
'The path and file names:
MyPath = "C:\Users\x\Custom Office Templates"
MyFileName = "Test"
'Makes sure the path name ends with "\":
If Not Right(MyPath, 1) = "\" Then MyPath = MyPath & "\"
'Makes sure the filename ends with ".csv"
If Not Right(MyFileName, 4) = ".txt" Then MyFileName = MyFileName & ".txt"
End Sub

Answer 2

There are quite a few posts on this site to do with avoiding Select, and if you only need the values then Copy/Paste can be avoided too. It might be worth reading them to assist in the efficiency of your programming.
In terms of your loop, it might be easier to iterate the indexes of your array with a For i = 1 to n style loop. This enables you to reference your objects as a Range rather than the Variant required in the For Each ... style loop.
All together, the loop element of your code could be simplified to:
'Add these declarations
Dim wb As Workbook
Dim i As Long
For i = LBound(outputs) To UBound(outputs)
'...
Set wb = Workbooks.Add
wb.Worksheets(1).Range("A1") _
.Resize(outputs(i).Rows.Count, outputs(i).Columns.Count) _
.Value = outputs(i).Value2
Next

Answer 3

Without any additional changes, you should just change that line to Sheets("vbaTest").Range(output.address).Copy.
However, notice how you use .Copy, then paste special values? Instead, we can set the two ranges equal. Also, you should use workbook/worksheet variables, to keep those straight.
Here's a slightly tweaked code:
Sub Loops()
Dim MyPath As String, MyFileName As String
Dim output As Variant
Dim outputRange(1 To 3) As Range
Dim newWB As Workbook
Dim newWS As Worksheet, mainWS As Worksheet
Set mainWS = Worksheets("vbaTest")
With mainWS
Set outputRange(1) = .Range("output1", .Range("output1").End(xlDown))
Set outputRange(2) = .Range("output2", .Range("output2").End(xlDown))
Set outputRange(3) = .Range("output3", .Range("output3").End(xlDown))
End With
For Each output In outputRange
Debug.Print output.Address
'The path and file names:
MyPath = "C:\Users\x\Custom Office Templates"
MyFileName = "Test"
'Makes sure the path name ends with "\":
If Not Right(MyPath, 1) = "\" Then MyPath = MyPath & "\"
'Makes sure the filename ends with ".csv"
If Not Right(MyFileName, 4) = ".txt" Then MyFileName = MyFileName & ".txt"
'The new workbook becomes Activeworkbook:
Set newWB = Workbooks.Add
Set newWS = newWB.ActiveSheet
'Instead of .Copy/.PasteSpecial Values (meaning, you just want the text), we can
' skip the clipboard completely and just set the two ranges equal to eachother:
' Range([destination]).Value = Range([copy range]).Value
newWS.Columns("A").Value = mainWS.Range(output.Address).Value
With newWB
Application.DisplayAlerts = False
End With
'Brings back original sheet
mainWS.Activate
'Starts at the top of code
Next output
End Sub

Answer 4

The answer I've received from a user above that works the way I want it to is below:
Sheets("vbaTest").Range(output.address).Copy