Breaking a large table into smaller ones for export - sql

Question

I have a very large table in MS Access which exceeds the amount of lines Excel can hold. Due to licensing issues, we cannot use access as an external data source, we can, however use Excel to store the tables until we can use SQL Server which is coming in several months.
I have been tasked with breaking up the table into countries.
Getting a query for getting all the distinct countries is no problem.
Select distinct Country_Code
from AllCountries
But then I need to get a result set for each country.
I've been to several sites trying to figure this out before coming here.
I know it's a basic question, unfortunately, a stroke and 10 years away from the field has left me rusty.
I need to create these smaller tables 0r result sets and export them. I'm lost on this one.

Answer 1

Something like this?
PUBLIC FUNCTION exportFiles() AS Boolean
Dim db AS DAO.DATABASE
Dim qdf AS DAO.QueryDef
Dim rsRptGroup AS DAO.Recordset
Dim sSQL AS String
Dim sRptGroup AS String
Dim sPath AS String
Const sQryExport AS String = "qryExport"
sPath = Application.CurrentProject.PATH
SET db = CurrentDb
SET qdf = db.CreateQueryDef(sQryExport, sSQL)
qdf.NAME = sQryExport
' Get list of labeler values
sSQL = "SELECT DISTINCT labeler FROM qry_export"
Set rsRptGroup = db.OpenRecordset(sSQL, dbOpenDynaset, dbReadOnly)
' Now LOOP THROUGH list OF labeler VALUES AND CREATE a QUERY FOR EACH labeler
' so that the data can be exported
Do While Not rsRptGroup.EOF
sRptGroup = rsRptGroup("labeler")
sSQL = "SELECT * FROM qry_export WHERE labeler = '" & sRptGroup & "'"
qdf.sql = sSQL
DoCmd.TransferSpreadsheet acExport, acSpreadsheetTypeExcel9, sQryExport, sPath & "\xls\" & sRptGroup & ".xls"
rsRptGroup.MoveNext
Loop
rsRptGroup.Close
Set rsRptGroup = Nothing
db.Close
Set db = Nothing
exportFiles = True
End Function

Answer 2

Reconsider your setup as your claim is not entirely correct:
Due to licensing issues, we cannot use access as an external data
source
MS Access .mdb/.accdb files can be used by any PC machine regardless of the MSAccess.exe program which does require licensing. The underlying technology of MS Access is the JET/ACE SQL Engine which is a set of Windows .dll files, usually pre-installed on PC machines. Access is just a GUI that uses this engine by default.
So continue to use an actual relational database (.mdb/.accdb) files and not flatfile Excel worksheets for data storage and integrity. On machines without Access, files will show up with blank icons unable to be opened directly with any one program but can be connected with Excel or other langauges (PHP, R, Python, Java) via ODBC/OLEDB connections or COM objects --ADO or DAO. In fact, Windows computers can create .mdb/.accdb files without the full fledged Access program. Below are Excel macros for illustration:
CREATE DATABASE (with DAO)
Sub CreateDatabase()
On Error GoTo ErrHandle
Dim fso As Object
Dim olDb As Object, db As Object
Dim strpath As String
Const dbLangGeneral = ";LANGID=0x0409;CP=1252;COUNTRY=0"
strpath = "C:\Path\To\Access\Database.accdb"
' CREATE DATABASE
Set fso = CreateObject("Scripting.FileSystemObject")
Set olDb = CreateObject("DAO.DBEngine.120")
If Not fso.FileExists(strpath) Then
Set db = olDb.CreateDatabase(strpath, dbLangGeneral)
End If
Set db = Nothing
Set olDb = Nothing
Set fso = Nothing
MsgBox "Successfully created database!", vbInformation
Exit Sub
ErrHandle:
MsgBox Err.Number & " - " & Err.Description
Exit Sub
End Sub
CREATE TABLES (with ADO)
Sub CreateTables()
On Error GoTo ErrHandle
Dim strpath As String, constr As String
Dim objAccess As Object
Dim conn As Object
strpath = "C:\Path\To\Access\Database.accdb"
' CONNECT TO DATABASE
constr = "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=" & strpath & ";"
Set conn = CreateObject("ADODB.Connection")
conn.Open constr
' CREATE TABLES
conn.Execute "CREATE TABLE Clients (" _
& " ClientID AUTOINCREMENT," _
& " ClientName TEXT(255)," _
& " Address TEXT(255)," _
& " Notes TEXT(255)," _
& " DateCreated DATETIME" _
& ");"
conn.Execute "CREATE TABLE Orders (" _
& " OrderID AUTOINCREMENT," _
& " ClientID INTEGER," _
& " Item TEXT(255)," _
& " Price DOUBLE," _
& " OrderDate DATETIME," _
& " Notes TEXT(255)" _
& ");"
' CLOSE CONNECTION
conn.Close
Set conn = Nothing
MsgBox "Successfully created Clients and Orders tables!", vbInformation
Exit Sub
ErrHandle:
MsgBox Err.Number & " - " & Err.Description
Exit Sub
End Sub
Additionally, if you require a GUI application of MS Access with forms, reports, macros, and modules, only one person (developer) needs to have the full fledged MS Access to make design changes to database. Meanwhile, all others (users) can use free Runtime versions available for download via Microsoft.com: 2007 / 2010 / 2013 / 2016. Just be sure to have database run without need of a Navigation Pane (i.e., Main Menu navigation).