What is intermittently breaking my short block of VBA? - vba

Question

As per this post I have fixed the object checker. Sometimes the code will run fine for 10 entries, getting them all correct, sometimes it'll run for five. Sometimes it'll get the entries wrong.
It always tends to fail on the getting innertext of the element. When it gets the Y/N result wrong, I don't know at all what's causing that.
Please help! It's driving me mad. I've error checked at every stage over and again.
Sub LetsAutomateIE()
Dim barcode As String
Dim rowe As Integer
Dim document As HTMLDocument
Dim Element As HTMLDivElement
Dim text As String
Dim pos As Integer
Set ie = CreateObject("InternetExplorer.Application")
rowe = 2
While Not IsEmpty(Cells(rowe, 2))
barcode = Cells(rowe, "B").Value
pos = 0
text = ""
Set document = Nothing
With ie
.Visible = False
.navigate2 "https://www.amazon.co.uk/s/ref=nb_sb_noss_1?url=search-alias%3Daps&field-keywords=" & barcode
Do Until ie.readyState = 4
Loop
End With
Set document = ie.document
If IsObject(document.getElementById("result_0")) = False Then GoTo Here
text = document.getElementById("result_0").innerText
If InStr(text, "STEELBOOK") Or InStr(text, "Steelbook") Or InStr(text, "Steel book") <> 0 Then pos = 1
If pos <> 0 Then Cells(rowe, 4) = "Y" Else Cells(rowe, 4) = "N"
Here:
rowe = rowe + 1
Wend
Set ie = Nothing
End Sub
Here is a selection of sample barcodes I was working with. I've never managed to get through these successfully.
5030305517076
5030305517816
5060223767925
5060223767949
5060223767956
5060223767970
5060223767994
8717418358563
8717418365851
Thank you so much,
Sam

Answer 1

One problem is the fact that for some barcodes no results are found.
If you would test your code with IE.Visible = true then you will see text like this:
Your search "5060223767949" did not match any products.
Another problem is the condition IsObject(document.getElementById("result_0")) = False. This doesn't work well, because IsObject(Nothing) returns true. Better would be to use If <variable-name> Is Nothing Then ....
The complete code. HTH
' Add reference to Microsoft Internet Controls (SHDocVw)
' Add reference to Microsoft HTML Object Library
Sub LetsAutomateIE()
Dim IE As SHDocVw.InternetExplorer
Dim barcode As String
Dim rowe As Integer
Dim document As HTMLDocument
Dim Element As HTMLDivElement
Dim result01 As HTMLListElement
Dim noResults As HTMLHeaderElement
Dim text As String
Dim pos As Integer
Dim url As String
rowe = 2
url = "https://www.amazon.co.uk/s/ref=nb_sb_noss_1?url=search-alias%3Daps&field-keywords="
Set IE = New SHDocVw.InternetExplorer
While Not IsEmpty(Cells(rowe, 2))
barcode = Cells(rowe, "B").Value
pos = 0
text = ""
IE.Navigate url & barcode
While IE.Busy Or IE.readyState <> READYSTATE_COMPLETE
DoEvents
Wend
Set document = IE.document
Set result01 = document.getElementById("result_0")
If result01 Is Nothing Then
Set noResults = document.getElementById("noResultsTitle")
If Not noResults Is Nothing Then MsgBox noResults.outerText
GoTo Here
End If
text = document.getElementById("result_0").innerText
If InStr(text, "STEELBOOK") Or InStr(text, "Steelbook") Or InStr(text, "Steel book") <> 0 Then pos = 1
If pos <> 0 Then Cells(rowe, 4) = "Y" Else Cells(rowe, 4) = "N"
Here:
rowe = rowe + 1
Wend
IE.Quit
Set IE = Nothing
End Sub
I'm actually looking just to check the title of the first returned
product on the page...
The title is displayed with h2 element within li with id result_0. So it is possible to limit the search just to this li element and search for first h2 element.
' text = document.getElementById("result_0").innerText
Dim h2Elements As IHTMLElementCollection
Dim h2 As HTMLHeadElement
Set h2Elements = result01.getElementsByTagName("h2")
If h2Elements.Length > 0 Then
Set h2 = h2Elements.Item(0)
text = h2.innerText
Debug.Print text
Else
MsgBox "Text not found"
End If
Output:
RED 2 Blu-ray Steelbook UK Exclusive
The Hunger Games With Mockingjay Pendant
The Hunger Games
The Hunger Games
Avengers Assemble BD Steelbook
Avengers Assemble Bonus Disc BD Retail

Answer 2

I had an issue with document.getElementById("result_0") throwing an error. My workaround was to test if the element was in the Document.Body.InnerHTML.
If you set DebugMode to True then the webpage with bad results is left open for further inspection.
The barcode will be marked NA if not found.
Option Explicit
Sub LetsAutomateIE()
Const DebugMode As Boolean = True
Dim barcode As String, text As String
Dim rowe As Integer
Dim doc As HTMLDocument, liResults As HTMLLIElement
Dim ie As Object
Set ie = CreateObject("InternetExplorer.Application")
rowe = 2
While Not IsEmpty(Cells(rowe, 2))
barcode = Cells(rowe, "B").Value
With ie
.Visible = False
.navigate2 "https://www.amazon.co.uk/s/ref=nb_sb_noss_1?url=search-alias%3Daps&field-keywords=" & barcode
Do Until ie.readyState = 4
Loop
End With
Set doc = ie.document
If InStr(doc.body.innerHTML, "li id=""result_0""") Then
Set liResults = doc.getElementById("result_0")
text = liResults.innerText
Cells(rowe, 4) = IIf(InStr(text, "STEELBOOK") Or InStr(text, "Steelbook") Or InStr(text, "Steel book"), "Y", "N")
Else
Cells(rowe, 4) = "NA"
If DebugMode Then
ie.Visible = True
Set ie = CreateObject("InternetExplorer.Application")
End If
End If
rowe = rowe + 1
Wend
ie.Quit
Set ie = Nothing
End Sub