VB Script in excel to separate a paragraph in lines of 38 - vba

Question

I am working on taking a paragraph and separating that paragraph out in lines of 38 characters. What I was thinking was having a button for the employee to click and it will grab the information out of a certain cell, and place it in a text box of numerous lines that only have 38 characters, so the employee then can copy and paste it in our ERP system. The other kicker is I need a hard return after each line for it to probably be copied over. I was trying to use Str.Substring. Any help would greatly be appreciated.

Answer 1

So you need to take a paragraph and break it into a series of 38 character lines, separated by hard line breaks. The following code does so to the first cell in the worksheet (A1) and puts the clipboard, so all your users have to do is paste.
Sub main()
Dim x As Integer
Dim Output As String
Dim counter As Integer
Dim inputString As String
inputString = Cells(1, 1)
'We're going to go through the input string
'one character at a time
For x = 1 To Len(inputString)
'Each time through, we add one to our counter
counter = counter + 1
'When the counter reaches our breakpoint
If counter = 38 Then
'add a hard carriage return and line feed
Output = Output & vbCrLf
'Reset our counter
counter = 0
End If
'Append the current letter to the output
Output = Output & Mid(inputString, x, 1)
Next
'This puts the output string in the clipboard.
'You need to have a userform in your project for this to work
'or a reference to MSForms.
Dim cb As New DataObject
cb.SetText Output
cb.PutInClipboard
'This cleans up the clipboard object
Set cb = Nothing
End Sub

Answer 2

Here is a word wrap function that breaks the input string by space (replacing any new line characters) and fills the lines with whole words up to the specified margin. Unit tests attached to demonstrate typical usage.
Function getWordWrap(str As String, Optional margin As Long = 78) As String
Dim tokenArr() As String
Dim token As Variant
Dim line As String
Dim numChars As Long
tokenArr = Split(Replace(str, vbNewLine, " "))
For Each token In tokenArr
' if above margin - start a new line
If numChars > 0 And numChars + Len(token) + 1 > margin Then
getWordWrap = getWordWrap & Trim(line) & vbNewLine
numChars = 0: line = ""
End If
line = line & token & " "
numChars = Len(line) - 1
Next
getWordWrap = getWordWrap & Trim(line)
End Function
Sub testGetWordWrap()
' basic tests
Debug.Assert getWordWrap("Illum rerum qui.", 15) = "Illum rerum" & vbNewLine & "qui."
Debug.Assert getWordWrap("", 15) = ""
Debug.Assert getWordWrap("Illum rerum qui quia sequi excepturi adipisci iure.", 15) _
= "Illum rerum qui" & vbNewLine & "quia sequi" & vbNewLine & "excepturi" _
& vbNewLine & "adipisci iure."
' very long words
Debug.Assert getWordWrap("VeryVeryLongWord", 15) = "VeryVeryLongWord"
Debug.Assert getWordWrap("Illum rerum qui. VeryVeryLongWord", 15) _
= "Illum rerum" & vbNewLine & "qui." & vbNewLine & "VeryVeryLongWord"
Debug.Assert getWordWrap("Illum rerum qui. VeryVeryLongWord quia sequi", 15) _
= "Illum rerum" & vbNewLine & "qui." & vbNewLine & "VeryVeryLongWord" _
& vbNewLine & "quia sequi"
' pre-existing new lines
Debug.Assert getWordWrap("Illum rerum qui quia sequi" & vbNewLine & "excepturi adipisci iure.", 15) _
= "Illum rerum qui" & vbNewLine & "quia sequi" & vbNewLine & "excepturi" _
& vbNewLine & "adipisci iure."
' different margins
Debug.Assert getWordWrap("Illum rerum qui.", 1) = "Illum" & vbNewLine & "rerum" & vbNewLine & "qui."
Debug.Assert getWordWrap("Illum rerum qui.", 20) = "Illum rerum qui."
End Sub