Using checkboxes values in SQL "IN"-operator - vba

Question

I have a form with several checkboxes in it. Values of ticking checkboxes are used after in the SQL-query including in Excel-macro. I use these values in SQL "IN"-operator. So, everythig works. But I don't like the code for my macro.
For ticking checkboxes I use such code (and if there were more value the list would be very huge):
Public Location1 As String
Public Location2 As String
Public Location3 As String
Public Location4 As String
Private Sub OKCommandButton2_Click()
If CheckBox1.Value = True Then Location1 = "LocationValue1"
If CheckBox2.Value = True Then Location2 = "LocationValue2"
If CheckBox3.Value = True Then Location3 = "LocationValue3"
If CheckBox4.Value = True Then Location4 = "LocationValue4"
...
And for using it in SQl I use such code:
query = "SELECT Param1, Param2, Param3, Param4, 0, 0, Param5, 0 FROM Table1 " & _
"WHERE Param1 like'" & "%" & CraftDefinition.Craft & "%" & "'AND Param6>0 AND Param2 IN ('" & _
LocationDefinition.Location1 & "','" & LocationDefinition.Location2 & "','" & LocationDefinition.Location3 & "','" & _
LocationDefinition.Location4 & "')" & _
"ORDER BY Param2, Param3"
The question is: can I rewrite my code in more compact, laconic and sophisticated way? Maybe I should use another operator in SQL-part; maybe I can rewrite my VBA-part, for using only one parameter in SQl.
Thank you.

Answer 1

you can use the "controls" Feature and write your Value into the "TAG" from the checkbox
Dim TB As Control
Dim ChkBoxString As String
ChkBoxString = "("
For Each TB In Me.Controls
If TypeOf TB Is CheckBox Then
If TB.Value = True Then
ChkBoxString = ChkBoxString & TB.Tag & ", "
End If
End If
Next TB
ChkBoxString = ChkBoxString & ")"
ChkBoxString = Replace(ChkBoxString, ", )", ")")
So you can use your Script:
query = "SELECT Param1, Param2, Param3, Param4, 0, 0, Param5, 0 FROM Table1 " & _
"WHERE Param1 like'" & "%" & CraftDefinition.Craft & "%" & "'AND Param6>0 AND Param2 " _
IN " & ChkBoxString
Greets Ralf

Answer 2

Create function that return string expression with comma delimited, and set the value in the Tag property of the checkbox
Function GetExpression() As String
Dim contr As Control
Dim comma As String
Dim str As String
str = ""
For Each contr In UserForm1.Controls
comma = IIf(str <> "", ",", "")
If TypeName(contr) = "CheckBox" Then
If contr.Value = True Then str = str + comma + contr.Tag
End If
Next
GetExpression = str
End Function

Answer 3

If the sub that "makes" the query (or build the query string) is called while the Userform is still loaded then you can code as follows:
Option Explicit
Dim Locations As String '<--| UserForm scoped variable: all subs in the userform code pane can "see" it
Private Sub OKCommandButton2_Click()
Dim ctrl As Control
For Each ctrl In Me.Controls '<--| loop through userform controls
If TypeName(ctrl) = "CheckBox" Then '<--| consider only checkboxes
If ctrl.value Then Locations = Locations & "LocationValue" & Mid(ctrl.Name, 9, Len(ctrl.Name) - 8) & "','" '<--| if checkbox is checked then update 'Location' string
End If
Next ctrl
End Sub
Private Sub QuerySub() '<-- name of any Sub inside Userfom code pane that has to make the query
Dim Query As String
If Locations <> "" Then '<--| this Sub can "see" 'Locations' even if it has been initialized in a different Sub of the same Userform code pane
Query = "SELECT Param1, Param2, Param3, Param4, 0, 0, Param5, 0 FROM Table1 " & _
"WHERE Param1 like'" & "%" & CraftDefinition.Craft & "%" & "'AND Param6>0 AND Param2 IN ('" & _
Left(Locations, Len(Locations) - 3) & "')" & _
"ORDER BY Param2, Param3"
Else
' code to handle 'Locations' empty string
End If
End Sub

Answer 4

This seems a tiny bit wrong because you get IN ('', '', '', '') when unchecked, but if you don't mind that, then maybe something like this:
locations$ = Mid$( _
IIf(CheckBox1, "','LocationValue1", "") & _
IIf(CheckBox2, "','LocationValue2", "") & _
IIf(CheckBox3, "','LocationValue3", "") & _
IIf(CheckBox4, "','LocationValue4", ""), 4) ' works even is all unchecked
query = " ... AND Param2 IN ('" & locations & "') ORDER BY Param2, Param3"
or if all of the values really start with "LocationValue" then
Locations$ = Mid$(Replace(IIf(CheckBox1, ",1", "") & _
IIf(CheckBox2, ",2", "") & IIf(CheckBox3, ",3", "") & _
IIf(CheckBox4, ",4", ""), ",", "','LocationValue"), 4)