Error Checking Option Boxes - vba

Question

I'm trying to build in an error checking for two option boxes I have:
projectOptionbox
implementOptionbox
This is the current code I have right now for error checking a couple of other things, just unsure as to what kind of code is necessary for option boxes:
Function CheckInputs() As Boolean
If Not CheckControl(Me.nameTextbox, "Please enter your Name") Then Exit Function
If Not CheckControl(Me.projectTextbox, "Please enter a Project Name") Then Exit Function
If Not CheckControl(Me.initiativeCombobox, "Please select an Initiative") Then Exit Function
If Not CheckControl(Me.audienceCombobox, "Please select an Audience") Then Exit Function
If Not CheckControl(Me.impactCombobox, "Please select an Impact Type") Then Exit Function
If Not CheckControl(Me.hoursTextbox, "Please enter the amount of Monthly Hours") Then Exit Function
If Not CheckControl(Me.peopleTextbox, "Please enter the amount of People on the Project") Then Exit Function
If Not CheckControl(Me.lengthListbox, "") Then If Not CheckControl(Me.lengthListbox2, "Please select Project Length") Then Exit Function
CheckInputs = True
End Function
Private Function CountSelectedListBoxItems(lb As MSForms.ListBox) As Long
Dim i As Long
With lb
For i = 0 To .ListCount - 1
If .Selected(i) Then CountSelectedListBoxItems = CountSelectedListBoxItems + 1
Next i
End With
End Function
Function CheckControl(ctrl As MSForms.Control, errMsg As String) As Boolean
Select Case TypeName(ctrl)
Case "TextBox"
CheckControl = Trim(ctrl.Value) <> ""
Case "ComboBox"
CheckControl = ctrl.ListIndex <> -1
Case "ListBox"
CheckControl = CountSelectedListBoxItems(ctrl) > 0
' Case Else
End Select
If errMsg = "" Then Exit Function
If CheckControl Then Exit Function
ctrl.SetFocus
MsgBox errMsg
End Function

Answer 1

From what I gathered from the post, it sounds like you want to develop a method of confirming that an OptionButton within a group has been selected. (Not looking for an application error per se, but rather a violation of your business logic).
This is a bit more complicated than the checks on the other controls because the other controls are standalone. There are two options. (1) Since the OptionButton control doesn't actually support a null state, you can set a default option on the Form's Initialization. Then, irrespective of what the user does, one of the options will always be selected.
The other option is to use the GroupName property of the OptionButtons to put buttons into a group. (When optionbuttons are in a group, this ensures that one of them is selected). Next, you can loop through all of the controls looking for OptionButtons of the same GroupName, then check if at least one of them is selected. A helper function such as the one below should do the trick:
Private Function OptionBoxGroupHasASelection(inputControl As MSForms.Control) As Boolean
Dim ctrl As MSForms.Control
Dim sGroup As String
Dim bOutput As Boolean
If TypeName(inputControl) <> "OptionButton" Then
OptionBoxGroupHasASelection = False
Exit Function
End If
If inputControl.Value = True Then
OptionBoxGroupHasASelection = True
Exit Function
End If
sGroup = inputControl.GroupName
bOutput = False
For Each ctrl In Me.Controls
If TypeName(ctrl) = "OptionButton" Then
If ctrl.GroupName = sGroup Then
If ctrl.Value = True Then
bOutput = True
Exit For
End If
End If
End If
Next ctrl
OptionBoxGroupHasASelection = bOutput
End Function