How to set this dynamic range in vba? - vba

Question

Here are 3 worksheets.
Case:
I want to sum the days for each person. The result is displayed on worksheet-report.
The days information is stored in worksheet-day. The day is not fixed. The range of the days is dynamic which should be according to
row: that person row in worksheet-day
column :Worksheets("button").Cells(1, 2 ) to Worksheets("button").Cells(2, 2)
For example :
Worksheets("button").Cells(1, 2 ) 'store 3
Worksheets("button").Cells(2, 2 ) 'store 5
In column A of worksheet-report ,the sum of day of Peter ,Tom ,Mary should be calculated .The result should be displayed on column B correspondingly .
Then ,their sum of the days should be searched in worksheet-day and add up the total within the range (D:F 'because the value in worksheet("button"))
The result should be :
Peter: 2
Tom: 3
Mary: 3
Lastly,this result displayed on worksheet-report column B correspondingly .
Here is my code:
Sub gg()
row = Worksheets("report").Range("A" & Rows.Count).End(xlUp).row
Row2 = Worksheets("day").Range("A" & Rows.Count).End(xlUp).row
Dim rng As Range 'the range for sum
Dim row999 As Integer 'store the selected row index
For k = 2 To Row2 'check and store appropriate row
If Worksheets("report").Cells(1, k).Value = Worksheets("day").Cells(1, k).Value Then
row999 = ActiveCell.row
End If
Next k
rng = Range(Cells(Worksheets("button").Cells(1, 2), row999), Cells(Worksheets("button").Cells(2, 2), row999))
For j = 2 To row 'do the sum
Worksheets("report").Cells(2, i) = Application.WorksheetFunction.Sum(rng)
Next j
End Sub
I guess the rng is inaccurate here.
rng = Range(Cells(Worksheets("button").Cells(1, 2), row999), Cells(Worksheets("button").Cells(2, 2), row999))

Answer 1

The problem that you are having is that the names do not match. Tom is uppercase on Report and lower case on day. Mary has an extra space on the Day worksheet "mary ".
Try to use shorter variable names when possible so that you can read each line of code without having to scan back and forth with your eyes.
Sub ProcessDays()
Dim day1 As Integer, day2 As Integer
Dim i As Integer, j As Integer
Dim name1 As String, name2 As String
With Worksheets("button")
day1 = .Cells(1, 2)
day2 = .Cells(2, 2)
End With
With Worksheets("day")
For i = 2 To Worksheets("report").Range("A" & Rows.Count).End(xlUp).Row
For j = 2 To .Range("A" & Rows.Count).End(xlUp).Row
name1 = UCase(Trim(Worksheets("report").Cells(i, 1)))
name2 = UCase(Trim(.Cells(j, 1)))
If name1 = name2 Then
Set rng = .Range(.Cells(j, day1), .Cells(j, day2))
Worksheets("report").Cells(i, 2) = WorksheetFunction.Sum(rng)
End If
Next
Next
End With
End Sub

Answer 2

The first parameter passed to Cells is the row, and the second parameter is the column.
You should also qualify which worksheet the range is on.
So your line saying:
rng = Range(Cells(Worksheets("button").Cells(1, 2), row999), Cells(Worksheets("button").Cells(2, 2), row999))
should say
rng = Worksheets("day").Range(Cells(row999, Worksheets("button").Cells(1, 2)), _
Cells(row999, Worksheets("button").Cells(2, 2)))
However, you have a lot of other errors in your code. I believe what you want is:
Sub gg()
Dim lastrowReport As Long
Dim lastrowDay As Long
Dim rowReport As Long
Dim rowDay As Long
lastrowReport = Worksheets("report").Range("A" & Rows.Count).End(xlUp).row
lastrowDay = Worksheets("day").Range("A" & Rows.Count).End(xlUp).row
Dim rng As Range 'the range for sum
For rowReport = 2 To lastrowReport ' loop through each of the rows on the report
For rowDay = 2 To lastrowDay ' find the entry for this person on the days sheet
If Worksheets("report").Cells(rowReport, 1).Value = Worksheets("day").Cells(rowDay, 1).Value Then
set rng = Worksheets("day").Range(Worksheets("day").Cells(rowDay, Worksheets("button").Cells(1, 2)), _
Worksheets("day").Cells(rowDay, Worksheets("button").Cells(2, 2)))
Worksheets("report").Cells(rowReport, 2) = Application.WorksheetFunction.Sum(rng)
Exit For
End If
Next
Next
End Sub