Distributing Cell Data - sql

Question

I wrote some code today for work and I've ran into an issue where the command I provide the SQL server through VBA doesn't solicit the same quantity of information as if I were to execute the same exact command on the server itself. If I execute the code below in VBA, I get about 25 rows of 68 columns. If I execute the same command on the server itself, I get just over 1500 rows of 68 columns. What I'm doing is selecting either an order number or a date, in a form, and stripping the mountain of data to just what my customer is looking to find. I'm sure this isn't the best way to distribute data across a spreadsheet. I'm looking for suggestions and error corrections!
Thanks in advance,
Adam
Set conn = New ADODB.Connection
Set cmd = New ADODB.Command
constr = "Provider=REMOVEDFORPRIVACY"
If (ComboBox1.Value <> "" And ComboBox2.Value <> "") Or (ComboBox1.Value = "" And ComboBox2.Value = "") Then
MsgBox "Please select one search method.", vbOKOnly
ComboBox2.Value = ""
ComboBox1.Value = ""
ElseIf (ComboBox1.Value <> "" And ComboBox2.Value = "") Then
cmd.CommandText = "SELECT * FROM [Run_Data].[dbo].[RunLog_Data] WHERE SnapShot_Date = '" & ComboBox1.Value & "'"
conn.Open constr
cmd.ActiveConnection = conn
Set rst = cmd.Execute()
Do While Not rst.EOF
o = o + 1
If o > 67 Then
o = 1 'Column Position
n = n + 1 'Row Position
End If
Range(Cells(n, o), Cells(n, o)).Value = rst(o)
rst.MoveNext
Loop
rst.Close
conn.Close
ElseIf (ComboBox1.Value = "" And ComboBox2.Value <> "") Then
cmd.CommandText = "SELECT * FROM [Run_Data].[dbo].[RunLog_Data] WHERE OrderNumber = '" & ComboBox2.Value & "'"
conn.Open constr
cmd.ActiveConnection = conn
Set rst = cmd.Execute()
Do While Not rst.EOF
'Duplicate above and consolidate code
rst.MoveNext
Loop
rst.Close
conn.Close
End If

Answer 1

The issue you are having is that you are performing your rst.MoveNext after you have filled in each cell. Therefore in your first line of output you are picking up the first column of the first record, the second column of the second record, ... the 68th column of the 68th record. Then you are populating the second line of output with the 1st column of the 69th record, etc.
I believe you can replace your entire loop with
Cells(1,1).CopyFromRecordset rst
(replacing the Cells(1,1) with whatever cell you want to be the top-lefthand corner of your results)
but alternatively you could move your rst.MoveNext command inside your If statement, i.e.
If o > 67 Then
o = 1 'Column Position
n = n + 1 'Row Position
rst.MoveNext
End If

Answer 2

Private Sub acceptButton_Click()
Set conn = New ADODB.Connection
Set cmd = New ADODB.Command
constr = "REMOVEDFORPRIVACY"
Dim sel_str, sel_type As String
If (ComboBox1.Value <> "" And ComboBox2.Value <> "") Or (ComboBox1.Value = "" And ComboBox2.Value = "") Then
MsgBox "Please select one search method.", vbOKOnly
ComboBox2.Value = ""
ComboBox1.Value = ""
ElseIf (ComboBox1.Value <> "" And ComboBox2.Value = "") Then
sel_type = "SnapShot_Date"
sel_str = ComboBox1.Value
ElseIf (ComboBox1.Value = "" And ComboBox2.Value <> "") Then
sel_type = "OrderNumber"
sel_str = ComboBox2.Value
End If
cmd.CommandText = "SELECT * FROM [Run_Data].[dbo].[RunLog_Data] WHERE " & sel_type & " = '" & sel_str & "'"
conn.Open constr
cmd.ActiveConnection = conn
Set rst = cmd.Execute()
Cells(2, 1).CopyFromRecordset rst
rst.Close
conn.Close
Me.Hide
End Sub