Editing code to copy the whole row - vba

Question

I found some code that does most of what I need it to do but I need to copy the whole row where it finds the occurrence of the variable, not just the cell in which it finds the occurrence. Any thoughts on how to edit it to copy the cell in which it found the variable to the last cell in the row containing data?
Sub Copy_To_Another_Sheet_1()
Dim FirstAddress As String
Dim MyArr As Variant
Dim Rng As Range
Dim Rcount As Long
Dim I As Long
Dim NewSh As Worksheet
Dim Initiatives As Worksheet
Set Initiatives = ThisWorkbook.Worksheets("Initiatives")
With Application
.ScreenUpdating = False
.EnableEvents = False
End With
MyArr = Array("Components")
Set NewSh = Worksheets.Add
With Initiatives.Range("B3:B500")
Rcount = 0
For I = LBound(MyArr) To UBound(MyArr)
Set Rng = .Find(What:=MyArr(I), _
After:=.Cells(.Cells.Count), _
LookIn:=xlFormulas, _
LookAt:=xlPart, _
SearchOrder:=xlByRows, _
SearchDirection:=xlNext, _
MatchCase:=False)
If Not Rng Is Nothing Then
FirstAddress = Rng.Address
Do
Rcount = Rcount + 1
Rng.Copy NewSh.Range("A" & Rcount)
Set Rng = .FindNext(Rng)
Loop While Not Rng Is Nothing And Rng.Address <> FirstAddress
End If
Next I
End With
With Application
.ScreenUpdating = True
.EnableEvents = True
End With
End Sub

Answer 1

Change this line:
Rng.Copy NewSh.Range("A" & Rcount)
Into this:
Rng.EntireRow.Copy NewSh.Rows(Rcount)
This will copy the whole row of Rng into the whole row of index Rcount, as opposed to just doing a single cell of each.