How to increment a counter when a value is found in awk - awk

Question

I am trying to write an awk script. part of the code needs to count the number of times $10 (in the code below its 256) is a certain value.
The possibilities are 4, 8, 16, 32, 64, 128, 256
Each time one of these values appears I want a corresponding variable to be incremented by one.
My block of code is
{
if ($10 == "4") {bs_4k++}
else if ($10 == "8") {bs_8k++}
if ($10 == "16") {bs_16k++}
if ($10 == "32") {bs_32k++}
if ($10 == "64") {bs_64k++}
if ($10 == "128") {bs_128k++}
if ($10 == "256") {bs_256k++}
};
This is the format of the data:
259,0 23 1 0.000000000 0 C WS 167588096 + 256 [0]
259,0 23 2 0.000002073 0 C WS 167588352 + 256 [0]
259,0 23 3 0.000004040 0 C WS 167587840 + 256 [0]
And my code to print results:
END {
print "Number of 256k blocks: " 256k_bs;
print "Number of 128k blocks: "128k_bs;
print "Number of 64k blocks: " 64k_bs;
print "Number of 32k blocks: " 32k_bs;
print "Number of 16k blocks: " 16k_bs;
print "Number of 8k blocks: " 8k_bs;
print "Number of 4k blocks: " 4k_bs;
};
When I try to print the variable I get:
Number of 256k blocks: 256
Number of 128k blocks: 128
Number of 64k blocks: 64
Number of 32k blocks: 32
Number of 16k blocks: 16
Number of 8k blocks: 8
Number of 4k blocks: 4
Any help is appreciated.

Answer 1

An easier way to hadnle this in awk might be to use an array instead of a collection of distinct variables.
Using this awk script:
BEGIN{
for (i=4;i<=256;i=i*2) { valid[i] }
}
$10 in valid {
bs[$10]++
}
END {
for (n in bs) {
printf("Number of %dk blocks: %d\n", n, bs[n])
}
}
on the following input data:
259,0 23 1 0.000000000 0 C WS 167588096 + 256 [0]
259,0 23 2 0.000002073 0 C WS 167588352 + 256 [0]
259,0 23 3 0.000004040 0 C WS 167587840 + 256 [0]
259,0 23 3 0.000004040 0 C WS 167587000 + 32 [0]
259,0 23 3 0.000004040 0 C WS 167587001 + 64 [0]
gets me the following results:
$ awk -f i.awk input.txt
Number of 64k blocks: 1
Number of 32k blocks: 1
Number of 256k blocks: 3
Of course, if you want the output sorted, you can pipe it through sort, or structure your awk array differently. Such additions are left as an exercise for the reader. :-)

Answer 2

You're not using your variables in the END block. As such, the numeric part is being interpreted literally, then a variable k_bs is being evaluated (which is unset, so you get an empty string).
Change 256k_bs to bs_256k, etc.

Answer 3

you can achieve the same with unit toolset
$ cut -d' ' -f10 file | sort -nr | uniq -c
3 256
1 64
1 32
and format the result as desired.