Execute SAS macro for many parameters - sql

Question

I use the following code to insert rows to the table:
proc sql;
create table business_keys as
select name, memname
from sashelp.vcolumn
where 1=0;
quit;
%macro insert(list);
proc sql;
%do i=1 %to &max;
%let val = %scan(&list,&i);
insert into business_keys
select distinct name, memname
from sashelp.vcolumn
where upcase(memname) = "&list"
and upcase(name) like '%_ZRODLO_ID%'
and length(name) = 12;
%end;
quit;
%mend;
%insert(&name1);
Now it inserts me the same row many &max times.
I have to execute it for all macro variables (&name#), not only for &name1. How I can pass all variables at the same time? In principle, I want to loop through all of these table names:
%insert(&name1-&name&max)
%name1 = PEOPLE, %name2 = CREDITS, ... %name%max = ANY_TABLE_NAME
Where &name# is table name and &max is number of tables.

Answer 1

ok, now i understand what you want to do, it is actually quite simple:
%macro insert;
proc sql;
%do i=1 %to &max;
insert into business_keys
select distinct name, memname
from sashelp.vcolumn
where upcase(memname) = upcase("&&name&i") and upcase(name) like '%_ZRODLO_ID%' and length(name) = 12;
%end;
quit;
%mend;
%insert;
&&name&i resolves to &name1\&name2...\&namex which resolves to PEOPLE\CREDITS...\ANY_TABLE_NAME depending on i.

Answer 2

Sounds like you want to pass a "macro array" to your macro to process. Where by "macro array" I mean a series of macro variables that all consist of a base name and a numeric suffix. Like NAME1, NAME2, etc. It would be easier to do that by passing two parameters to your macro. One for the basename of the array and one for the upper limit (or max) index.
%macro insert(basename,max);
%local i;
...
%do i=1 %to &max ;
... &&basename&i ...
%end;
...
%mend insert;
So you might call the macro like this:
%let name1=PEOPLE;
%let name2=CREDITS;
%insert(NAME,2);
Personally I would avoid the macro array and instead store the list in a single macro variable. If the list is just SAS names (datasets, libraries, variables, formats, etc.) then just use space for the delimiter. If it is something like labels that could include spaces then use some other character like | for the delimiter. Then your macro would look more like this.
%macro insert(memlist);
%local i;
...
%do i=1 %to %sysfunc(countw(&memlist,%str( ))) ;
... %scan(&memlist,&i,%str( )) ...
%end;
...
%mend insert;
So you might call the macro like this:
%insert(PEOPLE CREDITS);

Answer 3

If list looks like PEOPLE,CREDITS,...,ANY_TABLE_NAME
you should define max variable as following:
%let max = %sysfunc(countw(&list,',')).
You will know the number of iterations.
%macro insert(list);
%let max = %sysfunc(countw(&list,',')).
proc sql;
%do i=1 %to &max;
%let val = %scan(&list,&i);
insert into business_keys
select distinct name, memname
from sashelp.vcolumn
where upcase(memname) = "&val" and upcase(name) like '%_ZRODLO_ID%' and length(name) = 12;
%end;
quit;
%mend;