WMI: How to determine InstanceName of active instance? - vba

Question

I'm still a bit shaky when dealing with WMI, but here's the scenario. My company has several models of HP laptops deployed across the domain, and we need to change the asset tag setting in the BIOS. This code works for all of our HP EliteBooks:
Set objWMIService = objSWbemLocator.ConnectServer( _
strComputer, "root\HP\InstrumentedBIOS")
'We have to search for the exact bios tag name because it varies by model
Set colItems = objWMIService.ExecQuery("SELECT * FROM HPBIOS_BIOSString", , 48)
For Each objItem In colItems
If InStr(1, objItem.Name, "Asset") Then strName = objItem.Name
Next
' Obtain an instance of the the class using a key property value.
Set objShare = objWMIService.Get( _
"HPBIOS_BIOSSettingInterface.InstanceName='ACPI\PNP0C14\0_0'")
' Obtain an InParameters object specific to the method.
Set objInParam = objShare.Methods("SetBIOSSetting").InParameters.SpawnInstance_()
' Add the input parameters.
objInParam.Properties_.item("Name") = strName
objInParam.Properties_.item("Value") = strAssetTag
objInParam.Properties_.item("Password") = "<utf-16/>" & strPassword
' Execute the method and obtain the return status.
' The OutParameters object in objOutParams is created by the provider.
Set objOutParams = objWMIService.ExecMethod( _
"HPBIOS_BIOSSettingInterface.InstanceName='ACPI\PNP0C14\0_0'", _
"SetBIOSSetting", objInParam)
Select Case objOutParams.return
Case 0
strReturn = "Success. Asset Tag " & strAssetTag & _
" will be configured the next time you reboot " & _
strComputer & "."
Case 1
strReturn = "1: Not Supported"
Case 2
strReturn = "2: Unspecified Error"
Case 3
strReturn = "3: Timeout"
Case 4
strReturn = "4: Failed"
Case 5
strReturn = "5: Invalid Parameter"
Case 6
strReturn = "6: Access Denied"
Case Else
strReturn = "..."
End Select
The problem is that on HP ZBooks, the InstaneName is ACPI\PNP0C14\1_0. So changing the line to the correct instance makes it work for the ZBooks but breaks it for the EliteBooks. Eg:
Set objShare = objWMIService.Get( _
"HPBIOS_BIOSSettingInterface.InstanceName='ACPI\PNP0C14\1_0'")
I could create two scripts, one for the EliteBooks and one for the ZBooks, but since there is always only one Active instance, I would rather create one script that gets that active instance. For example (non-working code that I wished worked):
Set objShare = objWMIService.Get( _
"HPBIOS_BIOSSettingInterface.Active='True'")
So, how can I find the InstanceName of the Active HPBIOS_BIOSSettingInterface?

Answer 1

So maybe this was too simple or maybe there's a better way to do this, but here's how I ended up solving it:
I simply reused the colItems object to get a collection of Instances. There should only be one, but I verify that I have the correct instance by checking it's .Active property.
'We have to search for the exact bios tag name because it varies by model
Set colItems = objWMIService.ExecQuery( _
"SELECT * FROM HPBIOS_BIOSString", , 48)
For Each objItem In colItems
If InStr(1, objItem.Name, "Asset") Then strTagName = objItem.Name
Next
'We have to search for the exact instance name because it varies by model
Set colItems = objWMIService.ExecQuery( _
"SELECT * FROM HPBIOS_BIOSSettingInterface", , 48)
For Each objItem In colItems
If objItem.Active = "True" Then
strInstanceName = objItem.InstanceName
End If
Next
' Obtain the active instance.
Set objShare = objWMIService.Get( _
"HPBIOS_BIOSSettingInterface.InstanceName='" & strInstanceName & "'")
Not sure if this is the cleanest method for doing this, but it works.