Adding Listbox Items as Email Attachments - vba

Question

I have a sub on a form which is intended to allow users to report bugs and suggest improvements to the form. I have it pretty much ready to go, but keep running into issues with adding attachments.
Sub Submit()
Dim OutApp As Object
Dim OutMail As Object
Dim Item
Dim STR As String, AdminOnly As String, TruncBox As String, STRAttachments As String
For Each cCont In Me.MultiPage1.SelectedItem.Controls
Select Case TypeName(cCont)
Case "TextBox"
If cCont.value = "Please enter a short description here." Or _
cCont.value = "Please enter a short description here." Then
MsgBox ("Please enter all information.")
Exit Sub
ElseIf cCont.value = "" Then
MsgBox ("Please enter all information.")
Exit Sub
End If
Case "ComboBox"
If cCont.value = "" Then
MsgBox ("Please enter all information.")
Exit Sub
ElseIf InStr(cCont.value, "Report") Then
TruncBox = "BUG"
Else
TruncBox = "SUGGESTION"
End If
End Select
Next
STR = "{email address redacted}"
If RecipientsListBox.ListCount = 0 Then
AdminOnly = MsgBox("Only admin will receive updates!", _
vbOKCancel + vbExclamation, "No Users on Watch List")
If AdminOnly = vbCancel Then
Exit Sub
Else
STR = STR
End If
Else
For Each Item In RecipientsListBox.List
STR = STR & ";" & Item
Next Item
End If
Application.ScreenUpdating = False
Set OutApp = CreateObject("Outlook.Application")
On Error GoTo cleanup
Set OutMail = OutApp.CreateItem(0)
On Error Resume Next
With OutMail
.to = STR
Call .Recipients.resolveall
.Subject = TruncBox & ": " & ActiveWorkbook.Name & ": " & ShortDescriptionTextBox
.Body = LongDescriptionTextBox
If AttachmentsListBox.ListCount = 0 Then
Else
For Each Item In AttachmentsListBox.List
STRAttachments = Item
.Attachments.Add STRAttachments
Next Item
End If
'.Send 'Or use Display
.Display
End With
On Error GoTo 0
Set OutMail = Nothing
cleanup:
Set OutApp = Nothing
Application.ScreenUpdating = True
End Sub
I have run through various attempts at looping through each item on the AttachmentsListBox control, and ready to ask for help. This latest attempt produced Run-time error '94': Invalid use of Null with the line STRAttachments = Item returning null in the highlighted section. Looking at what I already have, and comparing to other searches on the internet, I don't understand. I returned variant Item to STR in the line STR = STR & ";" & Item above, and I've seen other examples of strings being returned as attachments. What am I missing?

Answer 1

So, this is a problem that I have identified in the past, but I haven't thoroughly researched the root cause. ListBox.List returns a multi-dimensional array of ListObjects. So, even though you have a ListBox with 1 column, the List array has multiple columns. When you loop over with a For Each loop, it tries to access values in these other columns, which just result in a Null value. Try using a For loop with a counter, such as:
Private Sub UserFormButton_Click()
For i = 0 To Me.ListBox1.ListCount - 1
MsgBox Me.ListBox1.List(i)
Next i
End Sub