error '1004': Select method of Range class failed - vba

Question

I am sure that every person who reads the title would say "oh no, not again". But before posting this, I have read about 7-8 previous questions with similar title and no-one seemed to work. So this is the deal:
My workbook uses the Workbook_Open event to show a userform:
Sub Workbook_Open()
UserForm1.Show
End Sub
Userform1 includes a textbox and a listbox. The listbox is populated with data dynamically, according to user's typing in the textbox. So far everything ok.
When user clicks at a value inside the listbox, I want a specific cell to be selected. So I used this:
Private Sub ListBox1_Click()
Dim Cell As Range
With ThisWorkbook.Worksheets(1)
Set Cell = .Range("C3", .Cells(.Rows.Count, 3).End(xlUp)).Find(UserForm1.ListBox1.Text, LookIn:=xlValues)
.Range(Cell, Cell.Offset(0, 2)).Select
End With
End Sub
But as many others before me, I cannot make Select work properly and this code gave an error like the title.
I tried several things to make this code work.
-Tried Application.GoTo, using it instead of Select,as someone suggested.
-Tried to move the code of the ListBox1_Click event to a sub inside a standard module and call this sub with the ListBox1_Click event.
-Tried to select the worksheet first as others suggested.
-Tried Worksheets(1).Visible = True as someone else suggested.
-Tried to activate the main window of the application first with AppActivate Application.Caption.
-Tried to scroll to the desired cell instead of selecting:
Private Sub ListBox1_Click()
Dim foundRow As Integer
With ThisWorkbook.Worksheets(1)
foundRow = .Range("C3", .Cells(.Rows.Count, 3).End(xlUp)).Find(UserForm1.ListBox1.Text, LookIn:=xlValues).Row
End With
ActiveWindow.ScrollRow = foundRow - 1
End Sub
I also tried other less important changes but I'm stuck with it. The funny thing is that before using the Workbook_Open event, I had UserForm1 shown via a macro assigned to a button/shape in the worksheet and everything worked fine then.
Does anybody know how am I going to make Select work in my case?
On the other hand, it's well understood that Select causes a great deal of problems, so I'm not stuck with it. If anyone has a another way to have the same result I'm all ears.

Answer 1

I was able to replicate the issue, first of all I followed what you described, made a list and picked from it to see if would scroll into view, and it worked.
If I closed the form, changed the active sheet. and then run the form it failed with the error message you are seeing.
Trying a number of things I discovered you can't select a cell if it is not the active sheet (which is logical, a user can not click on a cell that is not on the sheet they are viewing)
The below Activate line should fix it.
Private Sub ListBox1_Click()
Dim Cell As Range
With ThisWorkbook.Worksheets(1)
Set Cell = .Range("C3", .Cells(.Rows.Count, 3).End(xlUp)).Find(UserForm1.ListBox1.Text, LookIn:=xlValues)
ThisWorkbook.Worksheets(1).Activate
.Range(Cell, Cell.Offset(0, 2)).Select
End With
End Sub

Answer 2

As noted by #ScotCraner and as shown in the sample code on MSDN you should first check if something has been found before using / showing it.
The following should work flawlessly:
Private Sub ListBox1_Click()
Dim Cell As Range
Application.DisplayStatusBar = True
With ThisWorkbook.Worksheets(1)
Set Cell = .Range("C3", .Cells(.Rows.Count, 3).End(xlUp)).Find(UserForm1.ListBox1.Text, LookIn:=xlValues, LookAt:=xlWhole)
If Not Cell Is Nothing Then
Application.StatusBar = "Found " & UserForm1.ListBox1.Text
.Activate
.Range(Cell, Cell.Offset(0, 2)).Select
Else
Application.StatusBar = "Couldn't find " & UserForm1.ListBox1.Text
End If
End With
End Sub
Note, that you are using UserForm1.ListBox1.Text which does not consider UserForm1.ListBox1.MultiSelect.