Faster way to lookup awk - awk

Question

I have a list in a file as follows (in actual around 335 K):
abc
efg
hij
I want to look for the presence of this list in some files-all of which have the same extension of .count such that my output would be i.e what's the binary count of the above list in each .count file:
abc 1
efg 0
hij 1
(just gives me a binary score of 1 for present and 0 for absent)
In my code I am looping through each file with extension of .count and look for binary score for above list for characters and I am looking for it as follows:
awk -v lookup="$block" '$1 == lookup {count++ ; if (count > 0) exit} END {if (count) print 1 ; else print 0}' $file.count
The lookup is taking forever and I wonder if there is another way to expedite the lookup?

Answer 1

first, this doesn't make much sense
{count++ ; if (count > 0) exit}
can you see why?
Second you can reduce the looping by loading up the lookup into an array, for example,
awk 'NR==FNR{a[$1];next} {print $1 in a}' lookupfile otherfiles*
will print the 1/0 digits for each line
to print the ids as well
awk 'NR==FNR{a[$1];next} {print $1, $1 in a}' lookupfile otherfiles*
UPDATE: fixed the typo
for your example
$ echo -e "abc\ndef\nghi" > lookup
$ echo ghi > file1
$ awk 'NR==FNR{a[$1];next} {print $1, $1 in a}' lookup file1
ghi 1
UPDATE2: enhanced example
It will be easier if the order didn't matter but this preserves the order too and can run multiple files at the same time. You can tweak printing the header (print f)
with this setup
$ echo -e "abc\ndef\nghi" > lookup
$ echo ghi > file1
$ echo abc > file2
you can run
$ awk 'NR==FNR{a[NR]=$1;c++;next}
FNR==1 && f{print f;
for(k=1;k<=c;k++) print a[k], a[k] in b; delete b}
{b[$1]; f=FILENAME}
END{print f;
for(k=1;k<=c;k++) print a[k], a[k] in b; delete b}' lookup file1 file2
file1
abc 0
def 0
ghi 1
file2
abc 1
def 0
ghi 0
Explanation
NR==FNR{a[NR]=$1;c++;next} is for loading up the lookup table into array
in order (awk arrays are actually hash structures and iteration order
can be random) and count the number of entries.
FNR==1 && f{print f; at the beginning of each file after the first
one print the filename
for(k=1...) print a[k], a[k] in b; delete b} iterate over the lookup
table in order and check the file processed before has the corresponding entry and remove the processed file values (in b)
{b[$1]; f=FILENAME} load up the entries for each file and set the
filename (which will be used above to defer printing after the first
file)
END{print f; ... same printing step explained above now for last
file.