Loading Cross Table With Multiple Levels in Flat Format in QlikView - qlikview

Question

Is it possible to load a cross table in QlikView which has multiple layers in columns and rows? This is an example of a table in Excel which I would like to load as a flat table in QlikView:

Answer 1

Its not trivial in the case of qlikview...BUT..luckly for you I keep a demo file that shows exactly how to accomplish loading multi header tables!
You can download it from here.
takes time to understand the logic so study it carefully.

Answer 2

This is pretty straightforward using the crosstable function. Assuming your static data columns (i.e. "Total_CountriesWithAlloc", "Total Countries incl. costs not allocated") are static and constant in number, you can perform a load * from your source to pick up the "new" month columns as they appear over time.
Here's a basic example (just drop the script into a new document and run it to see conceptually how it works).
[Data]:
CrossTable(Months, Amount, 2)
LOAD * INLINE [
StaticDataA,StaticDataB,Jan,Feb,Mar
AAA,XXX,10,20,30
BBB,YYY,41,41,41
CCC,ZZZ,72,82,92
];
Based on the clarifications, you could try something like this:
QUALIFY *;
[Headers]:
LOAD
RecNo() as RecordIndex
,*
FROM [lib://qlikid_graeme.smith/Multi Header.xlsx]
(ooxml, no labels, table is Sheet1)
WHERE RecNo() <4
;
[UnpivotedRawData]:
LOAD
*
FROM [lib://qlikid_graeme.smith/Multi Header.xlsx]
(ooxml, no labels, table is Sheet1)
WHERE RecNo() >=4
;
UNQUALIFY *;
[PivotedData]:
CrossTable(ColRef, Amount, 2)
LOAD
*
RESIDENT
[UnpivotedRawData]
;
DROP TABLE UnpivotedRawData;
RenameMapData:
LOAD 'UnpivotedRawData.A' as FromFieldName, CONCAT([Headers.A]) as ToFieldName Resident Headers;
CONCATENATE LOAD 'UnpivotedRawData.B' as FromFieldName, CONCAT([Headers.B]) as ToFieldName Resident Headers;
RenameMapDataMap:
Mapping Load * Resident RenameMapData;
DROP TABLE RenameMapData;
RENAME FIELDS USING RenameMapDataMap;
ConcatenatedHeaders:
LOAD 'UnpivotedRawData.C' as ColRef, CONCAT([Headers.C]) as ConcatenatedFieldName Resident Headers;
CONCATENATE LOAD 'UnpivotedRawData.D' as ColRef, CONCAT([Headers.D]) as ConcatenatedFieldName Resident Headers;
CONCATENATE LOAD 'UnpivotedRawData.E' as ColRef, CONCAT([Headers.E]) as ConcatenatedFieldName Resident Headers;
DROP TABLE Headers;
In this example I have just concatenated the 3 column header rows, but you have the Row ID, so you could easily adapt to split these into new fields if you want. Also, you should automate the creation of the ConcatenatedHeaders table above by iterating dynamically through the NoOfFields() in the table rather than hard coding it like I have above, particularly if you have a dynamic number of incoming columns.
This is the output in Qliksense (I have done this on QlikSense cloud as I am at home on my mac). Script should work in Qlikview too though.
If you need to split out the individual fields (as per clarified requirements), just replace the last section of the script with this:
ConcatenatedHeaders:
LOAD 'UnpivotedRawData.C' as ColRef, CONCAT([Headers.C],'~') as ConcatenatedFieldName Resident Headers;
CONCATENATE LOAD 'UnpivotedRawData.D' as ColRef, CONCAT([Headers.D],'~') as ConcatenatedFieldName Resident Headers;
CONCATENATE LOAD 'UnpivotedRawData.E' as ColRef, CONCAT([Headers.E],'~') as ConcatenatedFieldName Resident Headers;
DROP TABLE Headers;
JOIN(ConcatenatedHeaders)
LOAD
ColRef
,SubField(ConcatenatedFieldName, '~',1) as Row1Header
,SubField(ConcatenatedFieldName, '~',2) as Row2Header
,SubField(ConcatenatedFieldName, '~',3) as Row3Header
RESIDENT
ConcatenatedHeaders;
The data should look like this: