vb.net: override toString method for enums - vb.net

Question

I would like to override toString method for each enum value. For example, I know in Java it can be done as below:
public enum Language_Culture_Names{
English {
#Override
public String toString() {
return "en-GB";
}
},
Spanish {
#Override
public String toString() {
return "es-ES";
}
},
Catalan {
#Override
public String toString() {
return "ca-ES";
}
}
}
System.out.println(Language_Culture_Names.English); -> returns en-GB
System.out.println(Language_Culture_Names.Spanish); -> returns es-ES
System.out.println(Language_Culture_Names.Catalan); -> returns ca-ES
So how to do this in VB.NET?

Answer 1

Ideally you should use a Class customized for yourself, since Enums are numeric constants and not string constants.
However, if you must use Enum and are looking for a generic solution, this is how I would do it:
First, add a Module to your project, with the following code:
Imports System.ComponentModel
Imports System.Runtime.CompilerServices
Module Module1
<Extension()> _
Public Function ToString2(ByVal EnumConstant As [Enum]) As String
Dim fi As Reflection.FieldInfo = EnumConstant.GetType().GetField(EnumConstant.ToString())
Dim aattr() As DescriptionAttribute = DirectCast(fi.GetCustomAttributes(GetType(DescriptionAttribute), False), DescriptionAttribute())
If aattr.Length > 0 Then
Return aattr(0).Description
Else
Return EnumConstant.ToString()
End If
End Function
End Module
We name our function ToString2 because Enum.ToString already exists, and can't be overridden. You can name it anything else.
Now in your class where the Enum is declared, decorate the Enum Members with Description attribute:
Imports System.ComponentModel '<-- be sure to include this Namespace
Public Enum Language_Culture_Names
<Description("en-GB")> English = 1
<Description("es-ES")> Spanish = 2
<Description("ca-ES")> Catalan = 3
End Enum
And finally dump the Enum.ToString method and use our new Enum.ToString2 method instead.
e.g.
TextBox1.Text = Language_Culture_Names.English.ToString2()
HTH.

Answer 2

Finally I have used type-safe-enum Pattern as below:
Public NotInheritable Class LanguageCultureNames
Private ReadOnly name As String
Private ReadOnly value As Integer
Public Shared ReadOnly English As New LanguageCultureNames(0, "en-GB")
Public Shared ReadOnly Spanish As New LanguageCultureNames(1, "es-ES")
Public Shared ReadOnly Catalan As New LanguageCultureNames(2, "ca-ES")
Private Sub New(ByVal value As Integer, ByVal name As String)
Me.name = name
Me.value = value
End Sub
Public Overrides Function ToString() As String
Return name
End Function
End Class