Duplicating Sheets in Excel - vba

Question

I'm trying to construct a spreadsheet to track project data, with a worksheet for each project and an overview sheet that provides summary information. I constructed a sheet based on a sample set of projects, and it all seems to work the way I expected. Adding a new project takes a lot of care and feeding, though, so I decided to give the user a button to click, a dialog to ask for a project name, and let the script do the rest.
I created a template sheet (conveniently titled "Template"), and I've attempted to script duplication of that sheet to the end of the workbook using the Worksheets("Name").Copy method as suggested on MSDN. This attempt is reflected in the first few lines of code below. After that I take a template row and add it to the end of the list on the overview sheet (named "Dashboard").
What ends up happening (as far as I can tell) is that the sheet doesn't copy, the last sheet in the workbook gets selected, and ActiveSheet.Name = Name ends up renaming it, blowing up my dashboard sheet that uses INDIRECT to find and represent data.
Here's the code I currently have (inefficient as it is):
Sub AddSOW()
' Duplicate the template sheet
Dim Name As String
Name = InputBox("SOW Name")
Worksheets("Template").Copy After:=Sheets(Sheets.Count)
ActiveSheet.Name = Name
Sheets("Dashboard").Select
' Find the last row of data
FinalRow = Cells(Rows.Count, 1).End(xlUp).Row
' Loop through each row
For x = 2 To FinalRow
' Decide if to copy based on column A
ThisValue = Cells(x, 1).Value
If ThisValue = "Template" Then
Cells(x, 1).Resize(1, 50).Copy
NextRow = Cells(Rows.Count, 1).End(xlUp).Row + 1
Cells(NextRow, 1).Select
ActiveSheet.Paste
ActiveCell.Value = Name
End If
Next x
End Sub
No errors get thrown, it just doesn't work. Stepping through doesn't help either.

Answer 1

It turns out I was causing my own problem.
In order to ensure that the user doesn't modify the template worksheet, I had it hidden. Duplicating it was also duplicating the .Visible property setting, so the sheets were actually getting duplicated, but since they weren't visible, the last sheet in the book that was visible was getting selected, and therefore the one getting renamed.
I updated the code with some error checking so canceling the input box doesn't cause problems. Here's the working code.
Sub AddSOW()
Dim SName As String
SName = InputBox("SOW Name")
' Duplicate the template sheet
If SName <> "" Then
Worksheets("Template").Visible = True
Worksheets("Template").Copy After:=Sheets(Sheets.Count)
ActiveSheet.Name = SName
Worksheets("Template").Visible = False
Sheets("Dashboard").Select
' Find the last row of data
FinalRow = Cells(Rows.Count, 1).End(xlUp).Row
' Loop through each row
For x = 2 To FinalRow
' Decide if to copy based on column A
ThisValue = Cells(x, 1).Value
If ThisValue = "Template" Then
Cells(x, 1).Resize(1, 50).Copy
NextRow = Cells(Rows.Count, 1).End(xlUp).Row + 1
Cells(NextRow, 1).Select
ActiveSheet.Paste
ActiveCell.Value = SName
End If
Next x
End If
End Sub