Removing Duplicate from 2 datatables - vb.net

Question

I have 2 Datatables with column X. I want to delete the entire row if column x value is in both datatables. What is the best way to do this? This is what I tried but it doesn't work not sure if this is the best way anyway.
Private Function SplitData(ByVal dtSome As DataTable, ByVal dtAll As DataTable) As DataTable
' This Routine Creates the Plant DataDictionary
Dim SomelIndex As Integer = 0
Do While SomelIndex < dtSome.Rows.Count
Dim AlllIndex As Integer = 0
Do While AlllIndex < dtAll.Rows.Count
If dtAll.Rows(AlllIndex).Item("x").ToString = dtSome.Rows(SomelIndex).Item("x").ToString Then
'I have the below to removes because it doesn't appear to actually remove the rows even if it gets here
' dtAll.Rows.RemoveAt(AlllIndex)
dtAll.Rows.Remove(dtAll.Rows(AlllIndex))
Exit Do
Else
AlllIndex += 1
End If
Loop
SomelIndex += 1
Loop
Return dtAll
End Function

Answer 1

You could use LINQ to find the common rows and then remove them.
Private Function SplitData(ByVal dtSome As DataTable, ByVal dtAll As DataTable) As DataTable
' This Routine Creates the Plant DataDictionary
Dim common = (
From r1 In dtAll.AsEnumerable()
Join r2 In dtSome.AsEnumerable() On r1("x") Equals r2("x")
Select r1
).ToList()
For Each r In common
dtAll.Rows.Remove(r)
Next
Return dtAll
End Function
I don't know if this is the "best" way, but to me it makes it easier to see what is going on than the nested loops.
Note that DataTable.AsEnumerable requires a reference to System.Data.DataSetExtensions.dll.

Answer 2

Just before you return dtAll, add this line:
dtAll.AcceptChanges()
It will commit the changes you made since "the last time AcceptChanges was called"...or in your particular case, since you invoked the function.

Answer 3

Not sure what my problem was but this is a bit neater of a solution. Instead of using 2 do while loop I am using a for each and a Do While Loop. Prob not the most efficient way but the below definitely works and deletes the data
Public Shared Function SplitDataTables(ByVal dtSome As DataTable, ByVal dtAll As DataTable) As DataTable
For Each drSome As DataRow In dtSome.Rows
Dim intIndex As Integer = 0
Do While intIndex < dtAll.Rows.Count
If drSome.Item("X").ToString = dtAll.Rows(intIndex).Item("X").ToString Then
dtAll.Rows.Remove(dtAll.Rows(intIndex))
Exit Do
Else
intIndex += 1
End If
Loop
Next
Return dtAll
End Function