VB.Net : Writing SQL Table field into Link Label Parent Control - vb.net

Question

I have a bunch of link label controls stored in SQL. I have figured out how to pull them and create the link label but when I try to write the lnk.Parent Control I get "Unable to cast object of type 'system.string' to type 'system.windows.forms.control'. Is there a way to convert this?
Private Sub CreateLinkLabel(Lnk_DT As DataTable)
Try
For Each row As DataRow In Lnk_DT.Rows
lnk = New LinkLabel
lnk.Name = row("FLD_LnkName").ToString
lnk.Text = row("FLD_LnkName").ToString
lnk.Font = New Font("Sans Serif", 10, FontStyle.Bold)
lnk.Location = New Point(20, i)
lnk.Parent = row("FLD_LnkPanel")
lnk.Tag = row("Fld_LnkTag").ToString
lnk.AutoSize = True
AddHandler lnk.LinkClicked, AddressOf lnk_LinkClicked
i = i + 25
Next
Catch ex As Exception
MessageBox.Show(ex.Message)
End Try

Answer 1

try this:
For Each c As Control In Me.Controls
If TypeOf c Is Panel Then
If c.Name = row("FLD_LnkPanel") Then
lnk.Parent = c
End If
End If

Answer 2

The Parent property should be assigned to a Form object (or other container control) so I suppose that you should write lnk.Parent = Me but in any case the correct way to add controls to a container is through the Add method of the Controls control collection.
For example, to add the newly created label to the current form, you write this inside your loop
Me.Controls.Add(lnk)
Looking at your code it seems that the field row("FLD_LnkPanel") is the name of a Panel control on your form. If you want to add the created label to this panel then you should write
Private Sub CreateLinkLabel(Lnk_DT As DataTable)
Try
For Each row As DataRow In Lnk_DT.Rows
' Get the panel name '
Dim panelName = row("FLD_LnkPanel")
' Search the panel between the Form controls'
Dim panel = Me.Controls.OfType(Of Panel)
.FirstOrDefault(Function(x) x.Name = panelName)
' If you got it, then proceed with the label creation
if panel IsNot Nothing Then
lnk = New LinkLabel
lnk.Name = row("FLD_LnkName").ToString
lnk.Text = row("FLD_LnkName").ToString
lnk.Font = New Font("Sans Serif", 10, FontStyle.Bold)
lnk.Location = New Point(20, i)
' lnk.Parent = row("FLD_LnkPanel")'
lnk.Tag = row("Fld_LnkTag").ToString
lnk.AutoSize = True
AddHandler lnk.LinkClicked, AddressOf lnk_LinkClicked
i = i + 25
' Add the label to the panel child controls
panel.Controls.Add(lnk)
End If
Next
Catch ex As Exception
MessageBox.Show(ex.Message)
End Try
End Sub

Answer 3

Consider something like this:
Private Sub CreateUIControls(Lnk_DT As DataTable)
For Each row As DataRow In Lnk_DT.Rows
Dim isPanelNew As Boolean
Dim pnl As Panel = GetPanel(row, isPanelNew)
CreateLink(row, pnl)
If isPanelNew Then
pnl.Location = New Point(10, 20) ' whatever logic
End If
Next
End Sub
Private Function GetPanel(item As DataRow, ByRef isNew As Boolean) As Panel
isNew = False
Dim pnlItem As Panel = Nothing
Dim pnlName As String = item.Field(Of String)("FLD_LnkPanel")
' check if panel already exists on form.
Dim pnl As Panel = (From p In Controls.OfType(Of Panel)()
Where p.Name = pnlName
Select p).SingleOrDefault()
If pnl Is Nothing Then
pnlItem = New Panel
pnlItem.Width = 200 ' whatever logic
isNew = True
Else
pnlItem = pnl
End If
Return pnlItem
End Function
Private Sub CreateLink(item As DataRow, parentControl As Panel)
' get how many links are in the panel.
Dim linksCount = parentControl.Controls.OfType(Of LinkLabel).Count()
Dim lnk As New LinkLabel
With lnk
.Name = item.Field(Of String)("FLD_LnkName")
.Text = item.Field(Of String)("FLD_LnkName")
.Font = New Font("Sans Serif", 10, FontStyle.Bold)
.Tag = item.Field(Of String)("Fld_LnkTag")
.AutoSize = True
' increase panel height to fit the new link.
parentControl.Height = ((linksCount + 1) * 25) + 10
.Parent = parentControl
.Location = New Point(20, (linksCount * 25) + 3)
AddHandler .LinkClicked, AddressOf lnk_LinkClicked
End With
End Sub