Can't figure out Object required error - vba

Question

The purpose of the code is to send an email to a list of addresses. To determine the start point, a user form will appear asking for the stating Column and Row (with plans that as I improve, I'll add other options in).
I had the code working, however, I made some tweaks and not keep getting an Object required error which I've tried figuring out for hours without luck. Please can you take a look at my code and suggest where I might be going wrong?
NB. I also tried declaring all variables but it didn't fix the issue.
The error is on the Loop Until username.Value = ""
Sub cmdGo_Click()
Application.DisplayAlerts = False
i = cmbRow
If i = "" Then
Exit Sub
End If
username = cmbColumn
If username = "" Then
Exit Sub
End If
Select Case username
Case "A", "a"
username = Cells(i, "a").Value
Case "B", "b"
username = Cells(i, "b").Value
Case "C", "c"
username = Cells(i, "c").Value
Case "D", "d"
username = Cells(i, "d").Value
Case "E", "e"
username = Cells(i, "e").Value
End Select
Do
Dim OutApp As Object
Dim OutMail As Object
Set OutApp = CreateObject("Outlook.Application")
Set OutMail = OutApp.CreateItem(0)
On Error Resume Next
With OutMail
.To = username
.CC = ""
.BCC = ""
.Importance = 1
.Subject = "Hello"
.HTMLBody = "Message"
'display shows each email before sending
.Display
'send sends email automatically
' .Send
End With
On Error GoTo 0
Set OutMail = Nothing
Set OutApp = Nothing
Application.DisplayAlerts = True
i = i + 1
Loop Until username.Value = ""
End Sub

Answer 1

There are few syntax and understanding mistakes in the code. I have listed them below and refactored your code a bit to help to get it work as you desire.
It's always best to use Option Explicit at the top of each module and explicitly declare variables with the desired type
Place the setting of the username inside the loop so it resets each time with a new email based on the i = i+1 counter.
Rest of comments are in code:
Option Explicit
Sub cmdGo_Click()
Application.DisplayAlerts = False
If cmbRow = "" or cmbColumn = "" Then
Exit Sub
End If
Dim i As Long
i = cmbRow
Dim UserNameCol As String 'created a new variable just to get column letter so can be used later in the loop and removed the `Select Case` block.
UserNameCol = cmbColumn
'set outlook outside loop since you only need to call it once, doing it in loop creates unneccesary processing
Dim OutApp As Object
Dim OutMail As Object
Set OutApp = CreateObject("Outlook.Application")
Do Until Len(Cells(i, UserNameCol).Value) = 0 'will stop when blank cell appears
Dim UserName As String
UserName = Cells(i, UserNameCol).Value 'always will user whatever column choosen
Set OutMail = OutApp.CreateItem(0) 'this goes here because a new email is needed each time
On Error Resume Next
With OutMail
.To = UserName
'.CC = "" 'you can remove this lines because you are not putting anything in the field
'.BCC = "" 'you can remove this lines because you are not putting anything in the field
.Importance = 1
.Subject = "Hello"
.HTMLBody = "Message"
'display shows each email before sending
.Display
'send sends email automatically
'.Send
End With
On Error GoTo 0
i = i + 1
Loop
'destroy outlook when finished processing all mails
Set OutMail = Nothing
Set OutApp = Nothing
Application.DisplayAlerts = True
End Sub