How to save All excel Charts in one pdf then Email it - vba

Question

I would greatly appreciate it if you could help me with this, I am creating a dynamic excel sheet and I managed so far to create excel charts using Excel vba.
However, I am struggling with exporting all of the charts and one additional sheet to one pdf. I have around 15 excel charts and one excel sheet that I need to put in one pdf. And I need the excel sheet to be the first page in the pdf. Then email this pdf (all using vba).
Could you please help me on this! Your help is much appreciated. Thank you in advance!

Answer 1

Well you could Publish the workbook to PDF, just make sure your fist page is the first sheet
Option Explicit
Sub PDF_And_Mail()
Dim FileName As String
'// Call the function with the correct arguments
FileName = Create_PDF(Source:=ActiveWorkbook, _
OverwriteIfFileExist:=True, _
OpenPDFAfterPublish:=False)
If FileName <> "" Then
Mail_PDF FileNamePDF:=FileName
End If
End Sub
'// Create PDF
Function Create_PDF(Source As Object, OverwriteIfFileExist As Boolean, _
OpenPDFAfterPublish As Boolean) As String
Dim FileFormatstr As String
Dim Fname As Variant
'// Test If the Microsoft Add-in is installed
If Dir(Environ("commonprogramfiles") & "\Microsoft Shared\OFFICE" _
& Format(Val(Application.Version), "00") & "\EXP_PDF.DLL") <> "" Then
'// Open the GetSaveAsFilename dialog to enter a file name for the pdf
FileFormatstr = "PDF Files (*.pdf), *.pdf"
Fname = Application.GetSaveAsFilename("", filefilter:=FileFormatstr, _
Title:="Create PDF")
'// If you cancel this dialog Exit the function
If Fname = False Then
Exit Function
End If
'If OverwriteIfFileExist = False we test if the PDF
'already exist in the folder and Exit the function if that is True
If OverwriteIfFileExist = False Then
If Dir(Fname) <> "" Then Exit Function
End If
'Now the file name is correct we Publish to PDF
Source.ExportAsFixedFormat _
Type:=xlTypePDF, _
FileName:=Fname, _
Quality:=xlQualityStandard, _
IncludeDocProperties:=True, _
IgnorePrintAreas:=False, _
OpenAfterPublish:=OpenPDFAfterPublish
'If Publish is Ok the function will return the file name
If Dir(Fname) <> "" Then
Create_PDF = Fname
End If
End If
End Function
'// Email Created PDF
Function Mail_PDF(FileNamePDF As String)
Dim GMsg As Object
Dim gConf As Object
Dim GmBody As String
Dim Flds As Variant
Set GMsg = CreateObject("CDO.Message")
Set gConf = CreateObject("CDO.Configuration")
gConf.Load -1 ' CDO Source Defaults
Set Flds = gConf.Fields
With Flds
.Item("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = True
.Item("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1
.Item("http://schemas.microsoft.com/cdo/configuration/sendusername") = "GmailAddress#gmail.com"
.Item("http://schemas.microsoft.com/cdo/configuration/sendpassword") = "password"
.Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "smtp.gmail.com"
.Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
.Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25
.Update
End With
GmBody = "Hi there" & vbNewLine & vbNewLine
With GMsg
Set .Configuration = gConf
.To = "recip#email.com"
.CC = ""
.BCC = ""
.From = "Reply#something.com"
.Subject = "Important message"
.TextBody = GmBody
.AddAttachment FileNamePDF
.Send
End With
End Function
Most codes from Ron de Bruin